批量加载器问题

Question

我正在用一些奇特的东西制作批量游戏。我知道你可以弹出消息等等，但我感兴趣的是一个不同的弹出窗口：我想制作一个装载机。

例如，在执行一项任务后，将弹出此加载程序。 装载机完成后，批次将继续。我正在尝试制作类似于以下其中一种的装载机：

这是与（MSG）命令相同的弹出式样式。我想指定此加载栏的标题。批次可以实现吗？有没有办法使用.VBS完成此操作？

这就是我在批处理中生成其他弹出窗口的方法：

echo X=MsgBox("Message Description",0+16,"Title") >msg.vbs

Answer 1

您可以尝试这样的事情：

在名为loadbar.bat的文件中，复制此：

@echo off
setlocal EnableDelayedExpansion

set max=16
SET "var="&for /f "delims=0123456789" %%i in ("%2") do set "var=%%i"
if not defined var if not "%~2"=="" set "max=%~2"
title Loading... 
if not "%~3"=="" title "%~3"
color 0a
set "top=É"
set "spaces="
set "bottom=È"
for /L %%i in (1,1,%max%) do (
   set "top=!top!Í"
   set "spaces=!spaces! "
   set "bottom=!bottom!Í"
)
set "top=!top!»"
set "bottom=!bottom!¼"

set /A loadnum=0, loadNum1=max-1
set "load="

:Loading
set "load=%load%²"
(
cls
echo                                 Loading "%~1"
echo                                 %top%
echo                                 º%load%!spaces:~0,%loadnum1%!º
echo                                 %bottom%
)
ping localhost -n 2 >nul
set /A loadnum+=1, loadnum1-=1
if %loadnum% lss %max% goto Loading

cls
timeout 1 >nul
title
color
exit

在游戏中，您可以像这样显示加载栏：

@echo off
start /wait loadbar "executing breach..." 5 "executing breach"
pause

加载栏的第一个参数是进度条上方的文本，第二个是最大数字，第三个是标题。