显示ZipFiles类的进度

Question

我很想知道，我怎么能得到这个百分比，所以我可以在进度条上显示它？

ZipFile.CreateFromDirectory("C:\temp\folder", "C:\temp\folder.zip")

以及

ZipFile.ExtractToDirectory("C:\temp\folder.zip", "C:\temp\folder")

Answer 1

这没有任何可用于报告进度的事件或回调。简单地说，你不能 .Net版本。如果您使用7-Zip库，则可以轻松完成此操作。

Answer 2

我在检查the identical question, asked for C# code的相关问题时遇到了这个问题。确实，.NET静态ZipFile类不提供进度报告。但是，使用早期版本的.NET之后的ZipArchive实现并不难。

关键是使用Stream包装器来报告读取和写入的字节，并在创建或提取存档时将其插入数据管道中。

我在C＃中编写了一个版本来回答另一个问题，因为我没有找到任何VB.NET示例，所以认为在这个问题上包含VB.NET版本会很有帮助。

（可以说，我可以在一个答案中包含这两个例子，并建议将其中一个问题作为另一个问题的副本关闭。但由于关闭投票会导致实际关闭，这是一个疑问。两个问题不会像它应该的那样明显。我认为为了获得最适合他们需求的解决方案的未来用户的最佳可见性，将其作为两个不同的问题更好。）

解决方案的基础是Stream包装类：

<强> StreamWithProgress.vb

Imports System.IO

Public Class StreamWithProgress
    Inherits Stream

    ' NOTE For illustration purposes. For production code, one would want To
    ' override *all* of the virtual methods, delegating to the base _stream object,
    ' to ensure performance optimizations in the base _stream object aren't
    ' bypassed.

    Private ReadOnly _stream As Stream
    Private ReadOnly _readProgress As IProgress(Of Integer)
    Private ReadOnly _writeProgress As IProgress(Of Integer)

    Public Sub New(Stream As Stream, readProgress As IProgress(Of Integer), writeProgress As IProgress(Of Integer))
        _stream = Stream
        _readProgress = readProgress
        _writeProgress = writeProgress
    End Sub

    Public Overrides ReadOnly Property CanRead As Boolean
        Get
            Return _stream.CanRead
        End Get
    End Property

    Public Overrides ReadOnly Property CanSeek As Boolean
        Get
            Return _stream.CanSeek
        End Get
    End Property

    Public Overrides ReadOnly Property CanWrite As Boolean
        Get
            Return _stream.CanWrite
        End Get
    End Property

    Public Overrides ReadOnly Property Length As Long
        Get
            Return _stream.Length
        End Get
    End Property

    Public Overrides Property Position As Long
        Get
            Return _stream.Position
        End Get
        Set(value As Long)
            _stream.Position = value
        End Set
    End Property

    Public Overrides Sub Flush()
        _stream.Flush()
    End Sub

    Public Overrides Sub SetLength(value As Long)
        _stream.SetLength(value)
    End Sub

    Public Overrides Function Seek(offset As Long, origin As SeekOrigin) As Long
        Return _stream.Seek(offset, origin)
    End Function

    Public Overrides Sub Write(buffer() As Byte, offset As Integer, count As Integer)
        _stream.Write(buffer, offset, count)
        _writeProgress?.Report(count)
    End Sub

    Public Overrides Function Read(buffer() As Byte, offset As Integer, count As Integer) As Integer
        Dim bytesRead As Integer = _stream.Read(buffer, offset, count)

        _readProgress?.Report(bytesRead)
        Return bytesRead
    End Function
End Class

包装器类可用于实现ZipFile静态方法的进度感知版本：

<强> ZipFileWithProgress.vb

Imports System.IO
Imports System.IO.Compression

NotInheritable Class ZipFileWithProgress

    Private Sub New()
    End Sub

    Public Shared Sub CreateFromDirectory(
        sourceDirectoryName As String,
        destinationArchiveFileName As String,
        progress As IProgress(Of Double))

        sourceDirectoryName = Path.GetFullPath(sourceDirectoryName)

        Dim sourceFiles As FileInfo() = New DirectoryInfo(sourceDirectoryName).GetFiles("*", SearchOption.AllDirectories)
        Dim totalBytes As Double = sourceFiles.Sum(Function(f) f.Length)
        Dim currentBytes As Long = 0

        Using archive As ZipArchive = ZipFile.Open(destinationArchiveFileName, ZipArchiveMode.Create)
            For Each fileInfo As FileInfo In sourceFiles
                ' NOTE: naive method To Get Sub-path from file name, relative to
                ' input directory. Production code should be more robust than this.
                ' Either use Path class Or similar to parse directory separators And
                ' reconstruct output file name, Or change this entire method to be
                ' recursive so that it can follow the sub-directories And include them
                ' in the entry name as they are processed.
                Dim entryName As String = fileInfo.FullName.Substring(sourceDirectoryName.Length + 1)
                Dim entry As ZipArchiveEntry = archive.CreateEntry(entryName)

                entry.LastWriteTime = fileInfo.LastWriteTime

                Using inputStream As Stream = File.OpenRead(fileInfo.FullName)
                    Using outputStream As Stream = entry.Open()
                        Dim progressStream As Stream = New StreamWithProgress(inputStream,
                            New BasicProgress(Of Integer)(
                                Sub(i)
                                    currentBytes += i
                                    progress.Report(currentBytes / totalBytes)
                                End Sub), Nothing)

                        progressStream.CopyTo(outputStream)
                    End Using
                End Using
            Next
        End Using
    End Sub

    Public Shared Sub ExtractToDirectory(
        sourceArchiveFileName As String,
        destinationDirectoryName As String,
        progress As IProgress(Of Double))

        Using archive As ZipArchive = ZipFile.OpenRead(sourceArchiveFileName)
            Dim totalBytes As Double = archive.Entries.Sum(Function(e) e.Length)
            Dim currentBytes As Long = 0

            For Each entry As ZipArchiveEntry In archive.Entries
                Dim fileName As String = Path.Combine(destinationDirectoryName, entry.FullName)

                Directory.CreateDirectory(Path.GetDirectoryName(fileName))
                Using inputStream As Stream = entry.Open()
                    Using outputStream As Stream = File.OpenWrite(fileName)
                        Dim progressStream As Stream = New StreamWithProgress(outputStream, Nothing,
                            New BasicProgress(Of Integer)(
                                Sub(i)
                                    currentBytes += i
                                    progress.Report(currentBytes / totalBytes)
                                End Sub))

                        inputStream.CopyTo(progressStream)
                    End Using
                End Using

                File.SetLastWriteTime(fileName, entry.LastWriteTime.LocalDateTime)
            Next
        End Using
    End Sub
End Class

IProgress(Of T)的.NET内置实现旨在用于存在应该引发进度报告事件的UI线程的上下文中。因此，当在我用来测试此代码的控制台程序中使用时，它将默认使用线程池来引发事件，从而允许无序报告。为了解决这个问题，上面使用了一个更简单的IProgress(Of T)实现，它只是直接和同步地调用处理程序。

<强> BasicProgress.vb

Class BasicProgress(Of T)
    Implements IProgress(Of T)

    Private ReadOnly _handler As Action(Of T)

    Public Sub New(handler As Action(Of T))
        _handler = handler
    End Sub

    Private Sub Report(value As T) Implements IProgress(Of T).Report
        _handler(value)
    End Sub
End Class

当然，有一个示例用于测试和演示代码。

<强>的Module1.vb

Imports System.IO

Module Module1

    Sub Main(args As String())
        Dim sourceDirectory As String = args(0),
            archive As String = args(1),
            archiveDirectory As String = Path.GetDirectoryName(Path.GetFullPath(archive)),
            unpackDirectoryName As String = Guid.NewGuid().ToString()

        File.Delete(archive)
        ZipFileWithProgress.CreateFromDirectory(sourceDirectory, archive,
            New BasicProgress(Of Double)(
                Sub(p)
                    Console.WriteLine($"{p:P2} archiving complete")
                End Sub))

        ZipFileWithProgress.ExtractToDirectory(archive, unpackDirectoryName,
            New BasicProgress(Of Double)(
                Sub(p)
                    Console.WriteLine($"{p:P0} extracting complete")
                End Sub))
    End Sub

End Module

有关此实施的其他说明，请参阅my answer to the related question。