Question

我有这个XSLT，可以很好地为xml文档中的每个节点生成一个xpath：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="text()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*">
    <xsl:copy>
      <xsl:attribute name="ez-xpath">
        <xsl:call-template name="genPath"/>
      </xsl:attribute>
      <xsl:attribute name="ez-xpath-guid">
         <xsl:value-of select="generate-id()"/>
      </xsl:attribute>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>    
  </xsl:template>

  <xsl:template name="genPath">
    <xsl:param name="prevPath"/>
    <xsl:variable name="currPath" select="concat('/',name(),'[',
      count(preceding-sibling::*[name() = name(current())])+1,']',$prevPath)"/>
    <xsl:for-each select="parent::*">
      <xsl:call-template name="genPath">
        <xsl:with-param name="prevPath" select="$currPath"/>
      </xsl:call-template>
    </xsl:for-each>
    <xsl:if test="not(parent::*)">
      <xsl:value-of select="$currPath"/>      
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

但是，我想修改此模板以使用local-name（）返回xpath。例如，假设我有一个像

那样生成的xpath

/Node1/Node2

但我想要

/*[local-name()='Node1']/*[local-name()='Node2']

代替

Answer 1

我不确定这是个好主意，但如果你想，请尝试：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="*">
    <xsl:copy>
        <xsl:attribute name="ez-xpath">
            <xsl:for-each select="ancestor-or-self::*">
                <xsl:text>/*[local-name()='</xsl:text>
                <xsl:value-of select="local-name()" />
                <xsl:text>'][</xsl:text>
                <xsl:value-of select="count(preceding-sibling::*[local-name() = local-name(current())]) + 1" />
                <xsl:text>]</xsl:text>
            </xsl:for-each>
        </xsl:attribute>
        <xsl:attribute name="ez-xpath-guid">
            <xsl:value-of select="generate-id()"/>
        </xsl:attribute>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

如何修改此xslt模板以返回local-name（）表示法？

1 个答案: