Question

我使用一些gradle依赖项创建了Android App。现在我想从这个项目创建*.jar（没有资源并单独添加）文件或*.aar文件。我尝试创建新的库项目（使用build.xml），复制了我的*.java和res文件并运行ant jar，我正逐一修复问题。有没有更好的解决方案呢？

Answer 1

你需要制作两个模块。第一个模块是jar。这应该是POJO s（Plain Old Java Object）而不是Android。第二个模块是aar。这可能取决于您的第一个项目，但添加Android特定的代码/资源。

然后您的项目（MyApp）结构将如下所示

MyApp/
MyApp/build.gradle
MyApp/settings.gradle
MyApp/PoJoProject/
MyApp/PoJoProject/build.gradle
MyApp/AndroidProject/
MyApp/AndroidProject/build.gradle

然后你的settings.gradle文件看起来像这样：

include ':PoJoProject', ':AndroidProject'

现在在模块中

在MyApp/PoJoProject/build.gradle中，您需要应用java插件。此模块将构建为所需的jar格式，可以在正常JVM的任何位置运行。

plugins {
    id 'java'
}

version '1.00'
group 'com.example.multimodule.gradle'

repositories {
    jcenter()
}

dependencies {
    compile 'com.google.code.gson:gson:2.5'
    testCompile 'junit:junit:4.12'
}

compileJava {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

在MyApp/AndroidProject/build.gradle您要应用android插件。此模块将构建为所需的aar格式，并且只能用作Android依赖项。

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.0.0-alpha3'
    }
}
apply plugin: 'com.android.application'

// version could be different from app version if needed
// `version` & `group` could also be in the top level build.gradle
version '1.00'
group 'com.example.multimodule.gradle'

repositories {
    jcenter()
}

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.2"

    defaultConfig {
        applicationId "com.example.multiproject.gradle.android"
        minSdkVersion 19
        targetSdkVersion 23
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    testOptions {
        unitTests.returnDefaultValues = true
    }
}

dependencies {
    // let the android `aar` project use code from the `jar` project
    compile project(':PoJoProject')
    testCompile 'junit:junit:4.12'
}

如何将Android Gradle应用程序打包到* .jar或* .aar文件

1 个答案: