Question

我正在尝试输入2个ascii文件并将它们输出到2个十六进制文件（sym.txt，sym2.txt）中，然后执行两个十六进制文件的总和，并将值的反转输出到最后一个文件（symout。 txt）。我真的看不出我做错了什么......谢谢你提前帮忙：D。

use strict;
use warnings 'all';

open my $in, "<", "f1.txt";
my $input = do { local $/; <$in> };

open my $out, ">", "sym.txt";
print $out unpack 'H*', $input;

open my $in1, "<", "f2.txt";
my $input1 = do { local $/; <$in1> };

open my $out1, ">", "sym2.txt";
print $out1 unpack 'H*', $input1;

    open(my $fh1, '<', 'sym.txt') or die $!;
    open(my $fh2, '<', 'sym2.txt') or die $!;
    open my $fh_out, '>', 'symout.txt' or die $!;

   until ( eof $fh1 or eof $fh2 ) {

    my @l1 = map hex, split '', <$fh1>;
    my @l2 = map hex, split '', <$fh2>;

    my $n = @l2 > @l1 ? @l2 : @l1;

    my @sum = map {
        no warnings 'uninitialized';
        $l1[$_] + $l2[$_];
    } 0 .. $n-1;

    @sum = map { sprintf '%X', $_ } @sum;

        print { $fh_out } reverse(@sum), "\n";
}

Answer 1

主要问题是您尚未关闭$out或$out1，因此打印到这些句柄的数据仍在内存中等待刷新

最好使用词法文件句柄（正如您所做）并添加块，以便当句柄超出范围时隐式关闭句柄

这是我的意思的一个例子。请注意，我还添加了use autodie，以避免检查每个open来电的状态（您应该这样做，但没有！）

use strict;
use warnings 'all';
use v5.14;
use autodie;

{
    my $input = do {
        open my $in, '<', 'f1.txt';
        local $/;
        <$in>
    };

    open my $out, '>', 'sym.txt';
    print $out unpack 'H*', $input;
}

{
    my $input = do {
        open my $in, '<', 'f2.txt';
        local $/;
        <$in>
    };

    open my $out, '>', 'sym2.txt';
    print $out unpack 'H*', $input;
}

open my $fh1, '<', 'sym.txt';
open my $fh2, '<', 'sym2.txt';

until ( eof $fh1 or eof $fh2 ) {

    my @l1 = map hex, split //, <$fh1>;
    my @l2 = map hex, split //, <$fh2>;

    my $n = @l2 > @l1 ? @l2 : @l1;

    my @sum = map {
        no warnings 'uninitialized';
        $l1[$_] + $l2[$_];
    } 0 .. $n-1;

    @sum = map { sprintf '%X', $_ } @sum;

    open my $out, '>', 'symout.txt';
    print { $out } reverse(@sum), "\n";
}

perl中十六进制值的总和

1 个答案: