Question

我的XML文件如下：

<worksheet>
<row>
<rowTitle>RT1</rowTitle>
<rowType>yesorno</rowType>
<subLine>subLine1Content</subLine>
<subLine>subLine2Content</subLine>
</row>
<row>
<rowTitle>RT2</rowTitle>
<rowType>operation</rowType>
<subLine>subLine1Content</subLine>
<subLine>subLine2Content</subLine>
<subLine>subLine3Content</subLine>
</row>
.
.
</worksheet>

在我的xsl中，在显示特定行的内容时，我想在html元素中添加一个类，它将指定行的类型。我尝试使用xsl：选择并为xsl：变量赋值，但这不起作用。我正在尝试将行显示为

<ol>
<li class="rowTypeBoolean">
RT1
<ul><li>subLineContent1</li>
<li>subLineContent2</li></ul>
</li>
<li class="rowTypeOptions">
RT2
<ul><li>subLineContent1</li>
<li>subLineContent2</li>
<li>subLineContent3</li></ul>
</li>
.    
.
</ol>

XSL文件摘要

<xsl:template match="row">
        <li class="rowClass ${className}">
            <xsl:choose>
                <xsl:when test="type = 'YESORNO'">
                    <xsl:variable name="className" select="rowTypeBoolean"/>
                </xsl:when>
                <xsl:when test="type = 'OPTIONS'">
                    <xsl:variable name="className" select="rowTypeOptions"/>
                </xsl:when>
                <xsl:when test="type = 'OPERATION'">
                     <xsl:variable name="className" select="rowTypeOperation"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="className" select="rowTypeOther"/>
                </xsl:otherwise>
            </xsl:choose>
            <span class="rowTitleClass">
                <xsl:value-of select="rowtitle"/>
            </span>
            <br/>
            <ul class="subLineListClass">
                <xsl:apply-templates select="subLine"/>
            </ul>
        </li>
</xsl:template>

Answer 1

您需要将其作为属性添加到元素中：

    <li>
        <xsl:choose>
            <xsl:when test="type = 'YESORNO'">
                <xsl:attribute name="className">rowTypeBoolean</xsl:attribute>
            </xsl:when>
            <xsl:when test="type = 'OPTIONS'">
                <xsl:attribute name="className">rowTypeOptions</xsl:attribute>
            </xsl:when>
            <xsl:when test="type = 'OPERATION'">
                <xsl:attribute name="className">rowTypeOperation"</xsl:attribute>
            </xsl:when>
            <xsl:otherwise>
                <xsl:attribute name="className">rowTypeOther"</xsl:attribute>
            </xsl:otherwise>
        </xsl:choose>
    </li>

Answer 2

最天真的解决方案是使用xsl:choose这样的指令：

<li>
    <xsl:attribute name="className"> 
        <xsl:choose> 
            <xsl:when test="type = 'YESORNO'">rowTypeBoolean</xsl:when> 
            <xsl:when test="type = 'OPTIONS'">rowTypeOptions</xsl:when> 
            <xsl:when test="type = 'OPERATION'">rowTypeOperation</xsl:when> 
            <xsl:otherwise>rowTypeOther</xsl:otherwise> 
        </xsl:choose> 
    </xsl:attribute>
</li>

其他方式是使用内嵌地图（或通过fn:document()），如：

<li class="{$map[@type = current()/type]|$map[not(@type)]}"/>

将此作为顶级元素

<map:map xmlns:map="map">
    <item type="YESORNO">rowTypeBoolean</item>
    <item type="OPTIONS">rowTypeOption</item>
    <item type="OPERATIONS">rowTypeOperation</item>
    <item>rowTypeOther</item>
</map:map>

<xsl:variable name="map" select="document('')/*/map:map/*" xmlns:map="map"/>

Answer 3

完全没有必要在转化中使用<xsl:choose> ：

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="worksheet">
  <ol>
   <xsl:apply-templates/>
  </ol>
 </xsl:template>

 <xsl:template match="row[rowType='yesorno']">
   <li class="rowTypeBoolean">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="row[rowType='operation']">
   <li class="rowTypeOperation">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="row[rowType='options']">
   <li class="rowTypeOptions">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="row">
   <li class="rowTypeOther">
     <xsl:apply-templates/>
   </li>
 </xsl:template>

 <xsl:template match="subLine[1]">
  <ul>
    <xsl:apply-templates select="../subLine" mode="process"/>
  </ul>
 </xsl:template>

  <xsl:template match="subLine" mode="process">
    <li><xsl:apply-templates/></li>
  </xsl:template>

</xsl:stylesheet>

应用于提供的XML文档：

<worksheet>
    <row>
        <rowTitle>RT1</rowTitle>
        <rowType>yesorno</rowType>
        <subLine>subLine1Content</subLine>
        <subLine>subLine2Content</subLine>
    </row>
    <row>
        <rowTitle>RT2</rowTitle>
        <rowType>operation</rowType>
        <subLine>subLine1Content</subLine>
        <subLine>subLine2Content</subLine>
        <subLine>subLine3Content</subLine>
    </row>
</worksheet>

生成想要的正确结果：

<ol>
    <li class="rowTypeBoolean">
        <rowTitle>RT1</rowTitle>
        <rowType>yesorno</rowType>
        <ul>
            <li>subLine1Content</li>
            <li>subLine2Content</li>
        </ul>
        <subLine>subLine2Content</subLine>
    </li>
    <li class="rowTypeOperation">
        <rowTitle>RT2</rowTitle>
        <rowType>operation</rowType>
        <ul>
            <li>subLine1Content</li>
            <li>subLine2Content</li>
            <li>subLine3Content</li>
        </ul>
        <subLine>subLine2Content</subLine>
        <subLine>subLine3Content</subLine>
    </li>
</ol>

请注意：

仅使用简单模板和<xsl:apply-templates> 。因此，最小化了发生错误的可能性。
此代码具有固有的可扩展性和可维护性。如果引入了新的行类型，则不需要更改任何现有模板 - 只需添加一个新的简短模板，该模板匹配具有row子项的rowType元素新价值。
可以在特殊的全局级命名空间元素和/或变量中指定rowType与class属性的相应值之间的映射（如在Alejandro的解决方案中完成，或者甚至在单独的XML文档中完成。然后我们只能有一个模板，匹配row。

将CSS类分配给XSL中的元素

3 个答案: