Question

我想尝试new rule based configuration in Gradle来配置我的插件。 Plugin的目标是将数据上传到云端存储，如Google Drive或S3。我需要为用户想要使用的每个存储配置一个配置。所以，我想要实现的是：

model {
    backup { // this is a container for all storages I want to support
        googleDrive {
            clientId = ''
            clientSecret = ''
            accessToken = ''
            refreshToken = ''
        }

        s3 {
           // S3 specific config (like API keys)
        }
    }
}

在我的插件中，我为backup元素配置规则源：

class BackupPlugin implements Plugin<Project> {

    static class Rules extends RuleSource {
        @Model
        void backup(BackupPluginExtension backupModel) {}
    }
}

@Managed
interface BackupPluginExtension {
    GoogleDrive getGoogleDrive()

    void setGoogleDrive(GoogleDrive googleDrive)
}

@Managed
interface GoogleDrive {
    String getClientId()

    void setClientId(String clientId)

    String getClientSecret()

    void setClientSecret(String clientSecret)

    String getAccessToken()

    void setAccessToken(String accessToken)

    String getRefreshToken()

    void setRefreshToken(String refreshToken)
}

但是，这不起作用：Could not find method googleDrive() for arguments [build_8w85xu7hrz3atgeg839d33hzl$_run_closure1_closure2_closure3@1b06ac95] on root project 'test'.。看起来它试图在backup内调用方法而不是配置嵌套bean。

那么，正确的语法是什么？

我知道命名集合，但问题是如何配置自定义bean层次结构。

Answer 1

以下是来自Gradle包.pyw的bean层次结构集合的模型示例。

samples/modelRules/ruleSourcePluginEach/包含BackupStorage和GoogleDrive存储空间的常用属性。

S3

Answer 2

玩了一段时间之后，似乎让googleDrive 只读（即删除setGoogleDrive() setter）可以修复你的问题（我得到在运行gradle model）时建立成功。

经过一些小修改（使用@Mutate代替Plugin.apply）后，它看起来像这样：

apply plugin: BackupPlugin

class BackupPlugin extends RuleSource {
    @Model
    void backup(BackupPluginExtension backupModel) {
    }

    @Mutate void createTasks(ModelMap<Task> tasks, BackupPluginExtension model) {
        tasks.create("backup") {
            doLast {
                // ... do stuff
                println "googleDrive.clientId = ${model.googleDrive.clientId}"
            }
        }
    }
}

@Managed
interface BackupPluginExtension {
    GoogleDrive getGoogleDrive()

//    void setGoogleDrive(GoogleDrive googleDrive)
}

@Managed
interface GoogleDrive {
    String getClientId()

    void setClientId(String clientId)

    String getClientSecret()

    void setClientSecret(String clientSecret)

    String getAccessToken()

    void setAccessToken(String accessToken)

    String getRefreshToken()

    void setRefreshToken(String refreshToken)
}

model {
    backup { // this is a container for all storages I want to support
        googleDrive  {
            clientId = 'someId'
            clientSecret = ''
            accessToken = ''
            refreshToken = ''
        }

    }
}

在此处运行gradle backup会打印googleDrive.clientId = someId。

基于Gradle规则的模型嵌套bean语法

2 个答案: