Question

我的情景是 - 我在.xls文件中有一组数据，在oracle数据库表中有另一组数据。我想使用excel vba导入两个数据，然后执行join（sql like），最后将数据保存在某个工作簿中。

问题 - 我不知道如何在vba中获取两组不同的数据然后执行连接。在.Net中有DataSet对象，我们可以在其中保存导入的数据，然后对其执行任何查询，但是vba我该怎么做？

Answer 1

使用ADO考虑以下示例。该代码允许从单个SQL查询（Jet SQL）中的多个数据源获取数据，特别是从.xlsx文件中创建联合，并将结果记录集放到工作表中。遗憾的是，我没有可用的Oracle数据源进行测试，但您也可以通过Oracle ODBC driver直接连接到Oracle（与任何其他数据库一样）。

代码放在Query.xlsm：

中

Option Explicit

Sub SqlUnionTest()

    Dim strConnection As String
    Dim strQuery As String
    Dim objConnection As Object
    Dim objRecordSet As Object

    strConnection = _
        "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "User ID=Admin;" & _
        "Data Source='" & ThisWorkbook.FullName & "';" & _
        "Mode=Read;" & _
        "Extended Properties=""Excel 12.0 Macro;"";"

    strQuery = _
        "SELECT * FROM [Sheet1$] " & _
        "IN '" & ThisWorkbook.Path & "\Source1.xlsx' " & _
        "[Excel 12.0;Provider=Microsoft.ACE.OLEDB.12.0;Mode=Read;Extended Properties='HDR=YES;'] " & _
        "UNION " & _
        "SELECT * FROM [Sheet1$] " & _
        "IN '" & ThisWorkbook.Path & "\Source2.xlsx' " & _
        "[Excel 12.0;Provider=Microsoft.ACE.OLEDB.12.0;Mode=Read;Extended Properties='HDR=YES;'] " & _
        "UNION " & _
        "SELECT * FROM [Sheet1$] " & _
        "IN '" & ThisWorkbook.Path & "\Source3.xlsx' " & _
        "[Excel 12.0;Provider=Microsoft.ACE.OLEDB.12.0;Mode=Read;Extended Properties='HDR=YES;'] " & _
        "ORDER BY ContactName;"

    Set objConnection = CreateObject("ADODB.Connection")
    objConnection.Open strConnection
    Set objRecordSet = objConnection.Execute(strQuery)
    RecordSetToWorksheet Sheets(1), objRecordSet
    objConnection.Close

End Sub

Sub RecordSetToWorksheet(objSheet As Worksheet, objRecordSet As Object)

    Dim i As Long

    With objSheet
        .Cells.Delete
        For i = 1 To objRecordSet.Fields.Count
            .Cells(1, i).Value = objRecordSet.Fields(i - 1).Name
        Next
        .Cells(2, 1).CopyFromRecordset objRecordSet
        .Cells.Columns.AutoFit
    End With

End Sub

注意，ThisWorkbook.Path不应在路径中包含'。否则，您必须将'替换为''来撤消它们。

此外，与Query.xlsm相同的文件夹中有三个data source个文件。

Source1.xlsx：

Source2.xlsx：

Source3.xlsx：

生成的工作表如下：

它适用于我的64位版Excel 2013。要使其与.xls和Excel 2003（未安装提供程序ACE.OLEDB.12.0）兼容，您必须将Provider=Microsoft.ACE.OLEDB.12.0;替换为Provider=Microsoft.Jet.OLEDB.4.0;，并将其替换为扩展属性{{ 1}} / Excel 12.0 Macro;与Excel 12.0;。您可以轻松地将Excel 8.0;子句和其他SQL内容添加到查询中。实际上，连接对象的数据源不限于代码所在的唯一WHERE文件。它可以是另一个数据源，与其中一个可用的提供程序兼容，可以是基于文件的，也可以是基于服务器的。在http://www.connectionstrings.com/

上查找数据源的更多连接字符串

如何在excel vba中加入从两个不同数据源创建的两个记录集

1 个答案: