备注换行

Question

我正在使用Indy 9中的TIdMappedPortTCP构建一个除了浏览器请求之外发送请求的工具。

我希望使用字符串#$d#$A（换行符）将其作为%0D%0A写在备忘录中 但它没有正常工作，正如你在图片中看到的那样。

我应该使用哪些正确的代码来完成这项工作？

procedure TForm1.IdMappedPortTCP1Execute(AThread: TIdMappedPortThread);
var
  memo:string;
begin
  memo:= Memo1.text;
  if Combobox4.text='Back' then begin
    AThread.NetData := AThread.NetData +memo  ;
    form2.Memo1.Lines.Add(AThread.NetData);

Answer 1

TIdMappedPortTCP是一个多线程组件。 OnExecute事件在工作线程的上下文中触发。您无法直接访问TMemo和TComboBox控件，就像您所示。您必须与UI线程同步才能安全，正确地访问它们。

尝试更像这样的事情：

uses
  ..., IdSync;

type
  TGetForm1BackMemoTextSync = class(TIdSync)
  protected
    FText: string;
    procedure DoSynchronize; override;
  public
    class function GetText: string;
  end;

  TAddToForm2MemoSync = class(TIdSync)
  protected
    FText: string;
    procedure DoSynchronize; override;
  public
    class procedure AddToMemo(const S: string);
  end;

procedure TGetForm1BackMemoTextSync.DoSynchronize;
begin
  if Form1.ComboBox4.Text = 'Back' then
    FText := Form1.Memo1.Text;
end;

class function TGetForm1BackMemoTextSync.GetText: string;
begin
  with Create do
  try
    Synchronize;
    Result := FText;
  finally
    Free;
  end;
end;

procedure TAddToForm2MemoSync.DoSynchronize;
begin
  Form2.Memo1.Lines.Add(FText);
end;

class procedure TAddToForm2MemoSync.AddToMemo(const S: string);
begin
  with Create do
  try  
    FText := S;
    Synchronize;
  finally
    Free;
  end;
end;

//...

procedure TForm1.IdMappedPortTCP1Execute(AThread: TIdMappedPortThread);
var
  memo: string;
begin
  memo := TGetMemoBackTextSync.GetText;
  if memo <> '' then begin
    AThread.NetData := AThread.NetData + memo;
    TAddToForm2MemoSync.AddToMemo(AThread.NetData);
  //...
end;

话虽如此，你根本不应该在备忘录文本中添加%0D%0A。备忘录中的每一行都已用换行符分隔。读取Memo.Text属性将返回一个字符串，其中每行由RTL的sLineBreak常量（在Windows上定义为#13#10）的值分隔。所以只需从文本中省略%0D%0A并输入自然换行符，然后让RTL为您处理其余的内容。

如果您必须在文本中保留%0D%0A，则必须剥离原生换行符，然后手动将%0D%0A转换为原生换行符，例如：

procedure TGetForm1BackMemoTextSync.DoSynchronize;
begin
  if Form1.ComboBox4.Text = 'Back' then
  begin
    FText := StringReplace(Form1.Memo1.Text, sLineBreak, '', [rfReplaceAll]);
    FText := StringReplace(FText, '%0D%0A', #13#10, [rfReplaceAll]);
  end;
end;