Question

我尝试使用this开发一个引导加载程序，但是当它运行时会显示：

disk read error!

如果我忽略它，在后面的部分，它会显示错误的内存映射。我也跟着其他一些消息来源但是徒劳无功。感觉就像我只是在复制他们正在做的事情。如果我做的甚至有点不同，每次都会产生一种新的错误。

我应该使用已经构建的引导加载程序还是要做什么？

磁盘加载错误代码如下：

[org 0x7c00]

    KERNEL_OFFSET equ 0x1000    
    mov [BOOT_DRIVE], dl        
    mov bp, 0x9000          
    mov sp, bp  
    mov bx, MSG_REAL_MODE       
    call print_string           
    call load_kernel            
    jmp $

print_string:
    pusha
    mov ah, 0x0e

loop:
    mov al,[bx]
    cmp al, 0
    je return
    int 0x10
    inc bx
    jmp loop

return:
    popa
    ret

disk_load: 
    push dx                                              
    mov ah, 0x02                                   
    mov al, dh                                          
    mov ch, 0x00                                    
    mov dh, 0x00                                     
    mov cl, 0x02                                    
    int 0x13                                           
    jc disk_error                                  
    pop dx                                               
    cmp dh, al                                         
    jne disk_error                                 
    ret

 disk_error :
   mov bx, DISK_ERROR_MSG 
   call print_string 
   jmp $

DISK_ERROR_MSG db "Disk read error!", 0

[bits 16]

load_kernel: 
    mov bx, KERNEL_OFFSET       
    mov dh, 15           
    mov dl, [BOOT_DRIVE]                      
    call disk_load                                                  
    ret

; Global variables
BOOT_DRIVE     db 0 
MSG_REAL_MODE db "Started in 16-bit Real Mode", 0 

; Bootsector padding 
times 510-($-$$) db 0 
dw 0xaa55

我使用此命令来组装和运行我的引导程序：

nasm boot.asm -f bin -o boot.bin && qemu-system-i386 boot.bin

我在这一点上陷入困境。我的引导程序显示disk read error。如果我在这个时候忽略它，那么它在执行我的kernel.c时会产生问题。它似乎使用了错误的内存映射。

Answer 1

＆＃34;他正在制作一份清单，他已经两次检查......＆＃34;

您的引导加载程序以实际地址模式启动，因此最好强制您的汇编程序使用16位代码。您可以通过在程序顶部编写[bits 16]来在NASM中实现此目的。
当您的引导加载程序启动时，BIOS会将其置于线性地址00007C00h。它可以通过多种方式对段和偏移的组合进行此操作当您明确写出[org 0x7C00]时，您（有点）期望此组合使段部分等于零。但这绝不是BIOS的义务！因此，您可以手动设置段寄存器（DS，ES和SS）。
您在 print_string 例程中使用的BIOS电传打字功能使用BL和BH作为参数。所以你永远不应该使用BX寄存器来处理你的文字。当然，一些BIOS不会使用这些BL和BH参数（不再是），但会尝试为最大的受众开发程序。
当您使用0x9000初始化SP寄存器时，您可以有效地设置一个堆栈，在您不注意的情况下，可以轻松覆盖它下面的程序！最好选择满足您需求的SS和SP组合，仅此而已。一个4608字节的堆栈在7C00h停留在bootsector之上并在9000h结束将需要：SS = 07E0h SP = 1200h。为避免8086硬件出现任何问题，最好在更改SS：SP时禁用中断。
您使用了pusha和popa条款。这些不是8086硬件上的有效说明。在编写健壮的软件时，我们应该测试硬件是否适合任务。但这里最简单的解决方案是只推/弹单个寄存器。
您已从BIOS功能中读取了从磁盘读取的返回值，但只是在传输的扇区数不正确时才会中止。这是一种错误的做法。当BIOS告诉您传输不完整时（如果您的BIOS未启用多轨道，则可能会发生这种情况），您必须重复呼叫剩余的扇区数。显然，必须调整一些参数：下一个头，可能是下一个柱面，并且总是扇区= 1。（完美的解决方案包括从BIOS检索磁盘几何或从磁盘上的BPB读取磁盘几何）。我假设基本的1.44 MB软盘操作。
从磁盘读取时，第一次没有成功，您应该多次重试。这样的第一次失败是完全正常的。五次重试是一个很好的价值。在两次尝试之间，您调用重置磁盘驱动器的BIOS功能。
为了确保QEMU能够实际读取这些额外的15个扇区，您应该填充此文件，使其总长度为16个扇区。您链接的text也是这样做的！

＆＃34;全部放在一起＆＃34;

[bits 16]
[org 0x7C00]

KERNEL_OFFSET equ 0x1000

xor  ax, ax
mov  ds, ax
mov  es, ax    
mov  [BOOT_DRIVE], dl
mov  ax, 0x07E0
cli
mov  ss, ax 
mov  sp, 0x1200
sti
mov  si, MSG_REAL_MODE       
call print_string           
call load_kernel            
jmp  $

print_string:
  push ax
  push bx
  push si
  mov  bx, 0x0007  ;BL=WhiteOnBlack BH=Display page 0
  mov  ah, 0x0E    ;Teletype function
 loop:
  mov  al, [si]
  cmp  al, 0
  je return
  int  0x10
  inc  si
  jmp  loop
 return:
  pop  si
  pop  bx
  pop  ax
  ret

disk_load:
  mov  [SECTORS], dh
  mov  ch, 0x00      ;C=0
  mov  dh, 0x00      ;H=0
  mov  cl, 0x02      ;S=2
 next_group:
  mov  di, 5         ;Max 5 tries
 again: 
  mov  ah, 0x02      ;Read sectors
  mov  al, [SECTORS]
  int  0x13
  jc   maybe_retry
  sub  [SECTORS], al ;Remaining sectors
  jz  ready
  mov  cl, 0x01      ;Always sector 1
  xor  dh, 1         ;Next head on diskette!
  jnz  next_group
  inc  ch            ;Next cylinder
  jmp  next_group
 maybe_retry:
  mov  ah, 0x00      ;Reset diskdrive
  int  0x13
  dec  di
  jnz  again
  jmp  disk_error
 ready:
  ret

disk_error:
  mov  si, DISK_ERROR_MSG 
  call print_string 
  jmp  $

DISK_ERROR_MSG db "Disk read error!", 0

load_kernel: 
  mov  bx, KERNEL_OFFSET       
  mov  dh, 15           
  mov  dl, [BOOT_DRIVE]                      
  call disk_load                                                  
  ret

; Global variables
BOOT_DRIVE     db 0
SECTORS        db 0
MSG_REAL_MODE  db "Started in 16-bit Real Mode", 0 

; Bootsector padding 
times 510-($-$$) db 0 
dw 0xAA55

; 15 sector padding
times 15*256 dw 0xDADA

将扇区加载到内存

1 个答案: