Question

我正在使用此样式表为epub创建一个opf文件，使用ncx文件（这是epub中的目录）作为主要输入：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version='2.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform' xmlns:xs='http://www.w3.org/2001/XMLSchema' xmlns:fn='http://www.w3.org/2005/xpath-functions' exclude-result-prefixes='xsl xs fn' xpath-default-namespace="http://www.daisy.org/z3986/2005/ncx/" xmlns="http://www.idpf.org/2007/opf" xmlns:dc="http://purl.org/dc/elements/1.1/" >
    <xsl:output method='xml' version='1.0' encoding='UTF-8' indent='no'/>

<xsl:param name="imgs" select="doc('../../EPUB/images.xml')"    />

    <xsl:template match='/'>
    <xsl:result-document href="EPUB/META-INF/container.xml" method="xml" encoding="UTF-8">
        <container xmlns="urn:oasis:names:tc:opendocument:xmlns:container" version="1.0">
         <rootfiles>
         <rootfile full-path="OPS/output.opf" media-type="application/oebps-package+xml"/>
         </rootfiles>
         </container>
    </xsl:result-document>
        <package version="2.0" unique-identifier="ID100">
            <metadata>
                <dc:title>E-Pub</dc:title>
                <dc:language>de</dc:language>
                <dc:identifier id="ID100">epub</dc:identifier>
                <dc:creator>sd</dc:creator>
            </metadata>
            <manifest>
                <item id="nav" href="nav.ncx" media-type="application/x-dtbncx+xml"/>
                <item id="css" href="Style/styles.css" media-type="text/css"/>
                <xsl:apply-templates select="//navPoint[content]"/>
                <xsl:copy-of select="$imgs"/>
            </manifest>
            <spine toc="nav">
                <xsl:apply-templates select="//navPoint[content]" mode="toc"/>
            </spine>
        </package>
    </xsl:template>
    <xsl:template match="ncx">
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="head">
    </xsl:template>
    <xsl:template match="meta">
    </xsl:template>
    <xsl:template match="docTitle">
    </xsl:template>
    <xsl:template match="navMap">
    </xsl:template>
    <xsl:template match="navLabel">
    </xsl:template>
    <xsl:template match="text">
    </xsl:template>
    <xsl:template match="navPoint[content]">
        <item id="{@id}" href="{content/@src}" media-type="application/xhtml+xml"/>
    </xsl:template>
    <xsl:template match="navPoint[content]" mode="toc">
        <itemref idref="{@id}"/>
    </xsl:template>
</xsl:stylesheet>

除了复制imgs参数引用的文件内容外，一切正常。那个文件看起来像这样：

<?xml version="1.0" encoding="UTF-8"?>
<images>
    <item id="d1e267_1" >
    <item id="d1e398_4" />
    <item id="d1e653_5" />
<!-- etc. -->
</images>

当我复制此文档时，如样式表中所示，根元素<images>也会复制到输出中，并带有空xmlns=""属性。

<images xmlns="">
    <item id="d1e267_1" >
    <item id="d1e398_4" />
    <item id="d1e653_5" />
<!-- etc. -->
</images>

如果我将images元素添加到doc-function，则不会复制任何内容，我想因为图像不在声明的默认命名空间中。我只想复制item元素。

如何在此处理此命名空间？我已经声明了一个默认命名空间（对于ncx文件），我已经声明了一个没有前缀的命名空间。

Answer 1

您需要转换节点然后复制意味着将其复制，具有相同的名称和命名空间，并且您的元素不在命名空间中，如果您复制它们，它们将保留在无命名空间中，并且父节点位于一个不同的命名空间，序列化程序添加xmlns=""，以维护空命名空间。

所以用<xsl:copy-of select="$imgs"/>替换<xsl:apply-templates select="$imgs/node()" mode="change-namespace"/>并添加模板

<xsl:template match="*" mode="change-namespace">
  <xsl:element name="{local-name()}">
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates mode="change-namespace"/>
  </xsl:element>
</xsl:template>

如果您只想转换item元素，请使用<xsl:apply-templates select="$imgs/*/*" mode="change-namespace"/>或<xsl:apply-templates xpath-default-namespace="" select="$imgs/images/item" mode="change-namespace"/>。

从不同文档xslt 2.0复制时出现名称空间问题

1 个答案: