Question

我正在寻找一种方法来引用当前用户＆＃34; MyVideos＆＃34; VB.NET中的文件夹。

我的目标是使用此引用来设置InitialDirectory对象的OpenFileDialog属性。 omething谎言：

OpenFileDialog1.InitialDirectory = My.Computer.FileSystem.SpecialDirectories.MyDocuments

在SpecialDirectories下，我无法找到MyVideos的属性。我SpecialDirectories下的唯一属性是：

.Desktop
.MyDocuments
.MyMusic
.MyPictures
.Programfiles
.Programs
.Temp

我错过了什么吗？还有其他方法可以访问这些信息吗？

我可以获取用户的根文件夹，并将其与＆＃34;视频＆＃34;结合使用，如下所示：

Dim vidPath As String = System.IO.Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.UserProfile), "Videos")

但是，假设用户未在其位置属性中更改其My Videos文件夹的位置。

如果用户更改了此位置设置，我想提出一种引用此位置的方法。

Answer 1

Environment.SpecialFolder枚举中缺少的文件夹可通过API调用获得。有几个C＃答案，主要是部分（获取特定文件夹）。所有（？）缺少的VB版本：

Public Partial Class NativeMethods

    <DllImport("shell32.dll")>
    Private Shared Function SHGetKnownFolderPath(<MarshalAs(UnmanagedType.LPStruct)> 
                                            rfid As Guid,
                                            dwFlags As UInt32,
                                            hToken As IntPtr,
                                            ByRef pszPath As IntPtr) As Int32
    End Function

   ' in order, below are:
    Public Enum ShellSpecialFolders
        Contacts
        Downloads
        Links
        Music
        Pictures
        SavedGames
        SavedSearches
        Videos
    End Enum

    Private Shared ShellFolderGuids As Guid() = {
                        Guid.Parse("{56784854-C6CB-462B-8169-88E350ACB882}"),
                        Guid.Parse("{374DE290-123F-4565-9164-39C4925E467B}"),
                        Guid.Parse("{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}"),
                        Guid.Parse("{4BD8D571-6D19-48D3-BE97-422220080E43}"),
                        Guid.Parse("{33E28130-4E1E-4676-835A-98395C3BC3BB}"),
                        Guid.Parse("{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}"),
                        Guid.Parse("{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}"),
                        Guid.Parse("{18989B1D-99B5-455B-841C-AB7C74E4DDFC}")
                                         }

    Friend Shared Function GetSpecialFolder(folder As ShellSpecialFolders) As String
        Dim ret As Int32
        Dim fPath As IntPtr
        ' == "Dont Vertify" flag:
        Dim SHFlag As UInt32 = &H4000

        ret = SHGetKnownFolderPath(ShellFolderGuids(folder), SHFlag,
                                   New IntPtr(0), fPath)

        If ret = 0 Then
            Return Marshal.PtrToStringUni(fPath)
        Else
            Return ""
        End If
    End Function

    ' Optional single purpose version
    Friend Shared Function GetSpecialVideoFolder() As String
        Return GetSpecialFolder(ShellSpecialFolders.Videos)
    End Function
'...
End Class

使用示例：

spath = NativeMethods.GetSpecialFolder(NativeMethods.ShellSpecialFolders.Videos)
Console.WriteLine("Videos are in: {0}", spath)

或者如果你想为它们写包装器：

spath = NativeMethods.GetSpecialVideoFolder()

如果您想获取默认文件夹（而不是C:\Users\USER NAME\...，则获得C:\Users\Default\...）将IntPtr参数更改为-1：

ret = SHGetKnownFolderPath(ShellFolderGuids(folder), SHFlag,
                               New IntPtr(-1), fPath)

结果：

注意：显然返回的文件夹不需要存在。特别是使用默认版本时，我的系统上实际上并不存在多个返回的文件夹。

如何在VB.net中引用当前Windows用户的视频文件夹路径

1 个答案: