Question

简单地说，我想从trust.pem中提取下面列出的整个私钥，并使用Perl将该文本保存到新文件（tmp6.pem）。我目前的实现只给了我第一个关键字母。

到目前为止，这是我的代码：

use warnings;
use strict;
use FileHandle;

use Fcntl qw(:DEFAULT :flock :seek); # import LOCK_* constants

my $F_IN = FileHandle->new("<trust.pem");
my $F_OUT = FileHandle->new(">tmp6.pem");

while (my $line = $F_IN->getline) {
    if ($line =~ m|(MIID)|) {
        $F_OUT->print("$1\n");
    }
}

$F_IN->close();
$F_OUT->close();

Answer 1

这将跳过输入文件的第一行和最后一行，使用input line number检测第一行并检查下一次读取是否会返回end of file以检测最后一行：

use strict;
use warnings;

open(my $in, '<', 'trust.pem') or die $!;
open(my $out, '>', 'tmp6.pem') or die $!;

while (<$in>) {
    next if $. == 1;
    last if eof($in);
    print $out $_;
}

close($in);
close($out);

如果您不介意将整个文件读入内存 - 在这种情况下完全没问题 - 您可以使用shift和pop删除第一个和最后一个数组中的行：

use strict;
use warnings;

open(my $in, '<', 'trust.pem') or die $!;
my @lines = <$in>;
close($in);

shift(@lines);
pop(@lines);

open(my $out, '>', 'tmp6.pem') or die $!;
print $out @lines;
close($out);

请注意，如果您有任何前导或尾随空白行，则前面的示例将无法正常工作。在这种情况下，我可能会做这样的事情，它跳过PEM文件页眉/页脚和只包含空格的行：

use strict;
use warnings;

open(my $in, '<', 'trust.pem') or die $!;
open(my $out, '>', 'tmp6.pem') or die $!;

while (<$in>) {
    next unless /\S/;
    next if /^-----/;
    print $out $_;
}

close($in);
close($out);

提取私钥并写入perl

1 个答案: