Question

我有一个项目（Delphi 10 Seattle，win32），这些菜单中包含许多菜单和许多项目。某些菜单项是在设计时创建的，其中一些是在运行时创建的。

我想要做的是在触发OnClick事件时记录有关TMenuItem的一些信息，例如名称/标题，时间戳等。

我可以简单地将一个过程调用添加到分配给TMenuItem OnClick事件的每个函数的开头，但我想知道是否有更优雅的解决方案。

另外需要注意的是，我已经尝试了Embarcadero's AppAnalytics，但我发现它没有给我我想要的信息或灵活性，而且相当昂贵。

编辑：我会添加更多信息，详细说明我考虑过哪些选项（我可能应该首先考虑这些选项）。

简单地为每个menuitem点击添加一个函数我想记录，这意味着要为很多函数执行此操作，并且必须将它添加到添加的每个新菜单项中。

procedure TSomeForm.SomeMenuItem1Click(Sender: TObject);
var
    item : TMenuItem;
begin
    item := Sender as TMenuItem;
    LogMenuItem(item);  // Simple log function added to the start of each menuitem click
end;

通过“更优雅的解决方案”，我的意思是可以添加“钩子”，以便在调用分配给OnClick事件的过程之前，所有TMenuItem OnClick事件都会触发另一个过程（将执行日志记录）。

或者我考虑的另一个选项是创建一个继承自TMenuItem的类，该类将覆盖TMenuItem.Click并在生成OnClick事件之前执行日志记录。但后来我不知道如何在没有大量工作重新设置菜单的情况下对设计时菜单项有用。

Answer 1

使用操作更容易实现。这样做的好处是，您可以选择菜单以外的UI元素调用的操作，例如工具栏，按钮等。

根据您的喜好使用action list或action manager。例如，对于动作列表，动作列表对象具有OnExecute事件，该事件在执行任何动作时触发。您可以侦听该事件，并记录正在执行的操作的详细信息。

Answer 2

我绝对同意行动是要走的路，但为了完整起见以及你很快想要使用旧式菜单调试应用程序的情况，这里有一个可以用于菜单项的单元。如果菜单项具有链接到它们的操作，它甚至可以工作，但它不会像TActionMainMenuBar这样的操作用于任何其他控件。所有调试代码都在此单元中，以保持您的正常代码无杂乱。只需将该单元添加到uses子句中，并使用任何适用的组件调用StartMenuLogging，例如菜单组件，表单组件甚至是Application！它下面树中的任何菜单项都会被挂钩。因此，您可以使用生产代码中的这两行来调试所有表单中的所有菜单单击。您可以使用StopMenuLogging停止，但它是可选的。警告：此单元未经过正确测试 - 我为此目的使用了一个旧的调试单元并将其清理干净，只是在表面上进行了测试。

unit LogMenuClicks;


interface

uses
  Classes;

procedure StartMenuLogging(AComponent: TComponent);
procedure StopMenuLogging(AComponent: TComponent);
procedure StopAllMenuLogging;


implementation

uses
  SysUtils,
  Menus;


type
  PLoggedItem = ^TLoggedItem;
  TLoggedItem = record
    Item: TMenuItem;
    OldClickEvent: TNotifyEvent;
  end;

  TLogManager = class(TComponent)
  private
    FList: TList;
    FLog: TFileStream;

    procedure Delete(Index: Integer);
    function FindControl(AItem: TMenuItem): Integer;
    procedure LogClick(Sender: TObject);
  protected
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;

    procedure AddControl(AItem: TMenuItem);
    procedure RemoveControl(AItem: TMenuItem);
  end;

  var
    LogMan: TLogManager = nil;

{ TLogManager }

constructor TLogManager.Create(AOwner: TComponent);
begin
  inherited;

  FLog := TFileStream.Create(ChangeFileExt(ParamStr(0), '.log'), fmCreate or fmShareDenyWrite);
  FList := TList.Create;
end;

destructor TLogManager.Destroy;
var
  i: Integer;
begin
  i := FList.Count - 1;
  while i >= 0 do
    Delete(i);
  FList.Free;

  FLog.Free;

  inherited;
end;

procedure TLogManager.Notification(AComponent: TComponent; Operation: TOperation);
begin
  if Operation = opRemove then
    RemoveControl(TMenuItem(AComponent));

  inherited;
end;

procedure TLogManager.Delete(Index: Integer);
var
  li: PLoggedItem;
begin
  li := FList[Index];

  with li^ do
  begin
    Item.RemoveFreeNotification(Self);
    Item.OnClick := OldClickEvent;
  end;

  Dispose(li);
  FList.Delete(Index);
end;

function TLogManager.FindControl(AItem: TMenuItem): Integer;
begin
  Result := FList.Count - 1;
  while (Result >= 0) and (PLoggedItem(FList[Result]).Item <> AItem) do
    Dec(Result);
end;

procedure TLogManager.AddControl(AItem: TMenuItem);
var
  li: PLoggedItem;
begin
  if not Assigned(AItem) then
    Exit;

  if FindControl(AItem) >= 0 then
    Exit;

  New(li);
  li.Item := AItem;
  li.OldClickEvent := AItem.OnClick;
  AItem.OnClick := LogClick;
  FList.Add(li);

  AItem.FreeNotification(Self);
end;

procedure TLogManager.RemoveControl(AItem: TMenuItem);
var
  i: Integer;
begin
  if Assigned(AItem) then
  begin
    i := FindControl(AItem);
    if i >= 0 then
      Delete(i);
  end;
end;

procedure TLogManager.LogClick(Sender: TObject);
var
  s: string;
begin
  s := Format('%s: %s' + sLineBreak, [TComponent(Sender).Name, FormatDateTime('', Now)]);
  FLog.WriteBuffer(s[1], Length(s));
  PLoggedItem(FList[FindControl(TMenuItem(Sender))]).OldClickEvent(Sender);
end;


procedure StartMenuLogging(AComponent: TComponent);

  procedure CheckControls(Comp: TComponent);
  var
    i: Integer;
  begin
    if Comp is TMenuItem then
      LogMan.AddControl(TMenuItem(Comp))
    else
      for i := 0 to Comp.ComponentCount - 1 do
        CheckControls(Comp.Components[i]);
  end;

begin
  if not Assigned(LogMan) then
    LogMan := TLogManager.Create(nil);

  CheckControls(AComponent);
end;

procedure StopMenuLogging(AComponent: TComponent);

  procedure CheckControls(Comp: TComponent);
  var
    i: Integer;
  begin
    if Comp is TMenuItem then
      LogMan.RemoveControl(TMenuItem(Comp))
    else
      for i := 0 to Comp.ComponentCount - 1 do
        CheckControls(Comp.Components[i]);
  end;

begin
  if Assigned(LogMan) then
    CheckControls(AComponent);
end;

procedure StopAllMenuLogging;
begin
  LogMan.Free;
end;


initialization

finalization
  if Assigned(LogMan) then
     LogMan.Free;

end.

记录MenuItem OnClick事件

2 个答案: