Question

我想知道XSLT 1.0如何完成一个转换，它将一个模板的结果作为另一个模板的输入传递到单个.xslt文件中：

原始XML输入＆gt; call-template（1）＆gt;重新格式化的XML＆gt;重新格式化的XML

上的call-template（2）

案例：

我想编写一个模板来重新排列xml，以便属性成为元素;然后在第一个生成的xml上运行另一个模板以删除重复项。我可以有两个xsl文件，并将第一个转换的结果传递给第二个。但是，我想在一个xslt中完成。

原始输入xml如下：

<?xml version="1.0" encoding="UTF-8"?>
<resources>
    <resource>
        <properties>
            <property name="name" value="Foo"/>
            <property name="service" value="Bar"/>
            <property name="version" value="1"/>
        </properties>
    </resource>
    <resource>
        <properties>
            <property name="name" value="Foo"/>
            <property name="service" value="Bar"/>
            <property name="version" value="2"/>
        </properties>
    </resource>
    <resource>
        <properties>
            <property name="name" value="AnotherFoo"/>
            <property name="service" value="AnotherBar"/>
            <property name="version" value="1"/>
        </properties>a
    </resource>
</resources>

当我应用以下xslt时：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    exclude-result-prefixes="msxsl">

    <xsl:output method="xml" indent="yes" />

    <xsl:template name="attributes-to-elements" match="/resources">
        <xsl:call-template name="get-resources" />
    </xsl:template>

    <xsl:template name="get-resources">
        <xsl:text>&#xa;</xsl:text>
        <products>
            <xsl:for-each select="resource">
                <xsl:call-template name="convert-attributes-to-elements" />
            </xsl:for-each>
        </products>
    </xsl:template>

    <xsl:template name="convert-attributes-to-elements">
        <product>
            <name>
                <xsl:value-of select="properties/property[@name='name']/@value" />
            </name>
            <service>
                <xsl:value-of select="properties/property[@name='service']/@value" />
            </service>
        </product>
    </xsl:template>
</xsl:stylesheet>

我能够在没有版本的情况下重新格式化xml，并获得不包含版本的输出，并且属性已成为元素：

<?xml version="1.0" encoding="UTF-8"?>
<products>
    <product>
        <name>Foo</name>
        <service>Bar</service>
    </product>
    <product>
        <name>Foo</name>
        <service>Bar</service>
    </product>
    <product>
        <name>AnotherFoo</name>
        <service>AnotherBar</service>
    </product>
</products>

现在，我想要的是将此修改后的xml作为输入xml 传递给某个模板并删除重复项。最后，我想得到一个xml：

<?xml version="1.0" encoding="UTF-8"?>
<products>
    <product>
        <name>Foo</name>
        <service>Bar</service>
    </product>
    <product>
        <name>AnotherFoo</name>
        <service>AnotherBar</service>
    </product>
</products>

Answer 1

如果你愿意，这一切都可以一次完成：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="k" 
         match="resource" 
         use="concat(properties/property[@name='name']/@value, '|', properties/property[@name='service']/@value)"
/>

<xsl:template match="/resources">
    <products>
        <xsl:apply-templates select="resource[count(. | key('k', concat(properties/property[@name='name']/@value, '|',      properties/property[@name='service']/@value))[1]) = 1]"/>
    </products>
</xsl:template>

<xsl:template match="resource">
    <product>
        <xsl:copy-of select="@id"/>
        <name>
            <xsl:value-of select="properties/property[@name='name']/@value" />
        </name>
        <service>
            <xsl:value-of select="properties/property[@name='service']/@value" />
        </service>
    </product>
</xsl:template>

</xsl:stylesheet>

Answer 2

我会使用一种模式来分离处理步骤，当然在XSLT 1.0中你还需要一个像exsl:node-set或msxsl:node-set这样的扩展函数来进一步处理在另一个中创建的结果树片段模板：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:exsl="http://exslt.org/common"
    exclude-result-prefixes="msxsl exsl">

    <xsl:output method="xml" indent="yes" />

    <xsl:key name="group" match="product" use="concat(name, '|', service)"/>

    <xsl:template match="@* | node()" mode="step2">
      <xsl:copy>
        <xsl:apply-templates select="@* | node()" mode="step2"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="product[not(generate-id() = generate-id(key('group', concat(name, '|', service))[1]))]" mode="step2"/>

    <xsl:template name="attributes-to-elements" match="/resources">
        <xsl:variable name="step1-rtf">
          <xsl:call-template name="get-resources" />
        </xsl:variable>
        <xsl:apply-templates select="exsl:node-set($step1-rtf)/*" mode="step2"/>
    </xsl:template>

    <xsl:template name="get-resources">
        <xsl:text>&#xa;</xsl:text>
        <products>
            <xsl:for-each select="resource">
                <xsl:call-template name="convert-attributes-to-elements" />
            </xsl:for-each>
        </products>
    </xsl:template>

    <xsl:template name="convert-attributes-to-elements">
        <product>
            <name>
                <xsl:value-of select="properties/property[@name='name']/@value" />
            </name>
            <service>
                <xsl:value-of select="properties/property[@name='service']/@value" />
            </service>
        </product>
    </xsl:template>
</xsl:stylesheet>

您需要检查您的XSLT处理器是否支持exsl:node-set，MSXML是否需要msxsl:node-set。

XSLT 1.0 - 在另一个模板

2 个答案: