Question

我想编写一个可以像这样转换XML的XSLT：

<Companies>
  <Company>
    <CompanyId>1</CompanyId>
    <CompanyType>1</CompanyType>
  </Company>
  <Company>
    <CompanyId>2</CompanyId>
    <CompanyType>2</CompanyType>
    <ParentCompanyId>1</ParentCompanyId>
  </Company>
</Companies>

进入这样的XML：

<Companies>
  <Company>
    <CompanyId>1</CompanyId>
    <CompanyType>1</CompanyType>
    <Company>
      <CompanyId>2</CompanyId>
      <CompanyType>2</CompanyType>
    </Company>
  </Company>
</Companies>

我该怎么做？

（我包括公司类型的原因是我可以直接从中获取节点的深度，这意味着深度为X的所有Company节点都将是Y类型）

Answer 1

使用 key 来选择当前公司的子项很容易。这适用于任何嵌套深度的递归。 CompanyType不是必需的。

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="child-by-parent" match="Company" use="ParentCompanyId" />

<xsl:template match="/Companies">
     <xsl:copy>
        <!-- select progenitors -->
        <xsl:apply-templates select="Company[not(ParentCompanyId)]" />
    </xsl:copy>
</xsl:template>

<xsl:template match="Company">
    <xsl:copy>
        <xsl:copy-of select="CompanyId | CompanyType"/>
        <!-- select children -->
        <xsl:apply-templates select="key('child-by-parent', CompanyId)"/> 
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

XSLT基于标记内容值转换XML

1 个答案: