Question

在火花列表中，我可以使用change事件找出已选择或取消选择的项目。已分派的IndexChangeEvent对象具有保存此信息的属性newIndex和oldIndex。

但是，如果允许多项选择，则此功能不再有效，因为newIndex和oldIndex可以引用仍然选定元素的索引。

解决方案是将selectedIndices向量复制到另一个变量，并在选择更改后将此变量与selectedIndices进行比较，但这似乎有些复杂。

有没有人知道是否有一种简单的方法可以让用户取消选择的索引/项目，而其他元素仍被选中？

Answer 1

您需要存储selectedIndicies并比较差异。

private static function findMissing(ar1:Array, ar2:Array):Array
{
    var missing:Array = [];
    for each(var item:Object in ar1)
    {
        if(ar2.indexOf(item) < 0)
            missing.push(item);
    }

    return missing;
}

Answer 2

您还可以使用

扩展自定义数据对象

一个可绑定的布尔属性： _selected，通过列表互动进行更新。
和可以解雇的事件它：selectionChanged。

在selected setter中 - 如果它实际发生了更改 - 您可以触发自己的冒泡selectionChanged事件，并在任何需要的地方捕获它。

SelectableItem.as - 表示列表行数据的自定义数据结构

[Bindable]
[Event(name="selectionChanged",type="flash.events.Event")]
public class SelectableItem
{
    public static const EVENT_SELECTION_CHANGED:String = 'selectionChanged';
    private var _selected:Boolean;
    private var _name:String;

    public function SelectableItem()
    {
    }

    public function get selected():Boolean
    {
        return _selected;
    }

    public function set selected(value:Boolean):void
    {
        if (_selected != value)
        {
            _selected = value;
            dispatchEvent(new Event(EVENT_SELECTION_CHANGED, true));
        }
    }

    public function get name():String
    {
        return _name;
    }

    public function set name(value:String):void
    {
        _name = value;
    }
}

<强> MyDataGrid.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:DataGrid xmlns:fx="http://ns.adobe.com/mxml/2009" 
    xmlns:s="library://ns.adobe.com/flex/spark" 
    xmlns:mx="library://ns.adobe.com/flex/mx" 
    allowMultipleSelection="true">
    <fx:Script>
        <![CDATA[
            import mx.controls.listClasses.IListItemRenderer;

            protected override function updateRendererDisplayList(r:IListItemRenderer):void
            {
                super.updateRendererDisplayList(r);
                if (r && r.data)
                    r.data.selected = DataGrid(r.owner).isItemSelected(r.data);
            }

        ]]>
    </fx:Script>
</mx:DataGrid>

<强> TestApplication.mxml

<fx:Script>
    <![CDATA[
        import mx.collections.ArrayCollection;
        import mx.events.FlexEvent;

        [Bindable]
        private var list:ArrayCollection = new ArrayCollection();

        protected function onCreationComplete(event:FlexEvent):void
        {
            for (var i:int = 0; i < 20; i++)
            {
                var item:SelectableItem= new SelectableItem();
                item.name = 'Item ' + i;
                item.addEventListener(SelectableItem.EVENT_SELECTION_CHANGED, onItemSelectionChanged);
                list.addItem(item);
            }
        }

        private function onItemSelectionChanged(event:Event):void
        {
            trace(event);
        }

    ]]>
</fx:Script>
<my:MyDataGrid dataProvider="{list}" width="100%" height="100%" />

我希望这会有所帮助。

找出具有多个选择的火花列表中的取消选择的项目

2 个答案: