给定一个typeglob，如何找到实际定义的类型？
在我的应用程序中，我们将PERL用作简单的配置格式。 我想要（）用户配置文件，然后能够看到定义了哪些变量，以及它们是什么类型。
代码:(有问题的质量咨询）
#!/usr/bin/env perl
use strict;
use warnings;
my %before = %main::;
require "/path/to/my.config";
my %after = %main::;
foreach my $key (sort keys %after) {
next if exists $before{$symbol};
local *myglob = $after{$symbol};
#the SCALAR glob is always defined, so we check the value instead
if ( defined ${ *myglob{SCALAR} } ) {
my $val = ${ *myglob{SCALAR} };
print "\$$symbol = '".$val."'\n" ;
}
if ( defined *myglob{ARRAY} ) {
my @val = @{ *myglob{ARRAY} };
print "\@$symbol = ( '". join("', '", @val) . "' )\n" ;
}
if ( defined *myglob{HASH} ) {
my %val = %{ *myglob{HASH} };
print "\%$symbol = ( ";
while( my ($key, $val) = each %val ) {
print "$key=>'$val', ";
}
print ")\n" ;
}
}
my.config：
@A = ( a, b, c );
%B = ( b=>'bee' );
$C = 'see';
输出：
@A = ( 'a', 'b', 'c' )
%B = ( b=>'bee', )
$C = 'see'
$_<my.config = 'my.config'
答案 0 :(得分：7)
在完全一般的情况下，由于perlref的以下摘录，你不能做你想做的事：
*foo{THING}如果尚未使用特定的THING，则会返回undef，但标量除外。如果尚未使用*foo{SCALAR}，则$foo会返回对匿名标量的引用。这可能会在将来的版本中发生变化。
但是如果您愿意接受任何标量必须具有要检测的定义值的限制，那么您可以使用诸如
之类的代码#! /usr/bin/perl
use strict;
use warnings;
open my $fh, "<", \$_; # get DynaLoader out of the way
my %before = %main::;
require "my.config";
my %after = %main::;
foreach my $name (sort keys %after) {
unless (exists $before{$name}) {
no strict 'refs';
my $glob = $after{$name};
print "\$$name\n" if defined ${ *{$glob}{SCALAR} };
print "\@$name\n" if defined *{$glob}{ARRAY};
print "%$name\n" if defined *{$glob}{HASH};
print "&$name\n" if defined *{$glob}{CODE};
print "$name (format)\n" if defined *{$glob}{FORMAT};
print "$name (filehandle)\n" if defined *{$glob}{IO};
}
}
会帮助你。
my.config的
$JACKPOT = 3_756_788;
$YOU_CANT_SEE_ME = undef;
@OPTIONS = qw/ apple cherries bar orange lemon /;
%CREDITS = (1 => 1, 5 => 6, 10 => 15);
sub is_jackpot {
local $" = ""; # " fix Stack Overflow highlighting
"@_[0,1,2]" eq "barbarbar";
}
open FH, "<", \$JACKPOT;
format WinMessage =
You win!
.
输出
%CREDITS FH (filehandle) $JACKPOT @OPTIONS WinMessage (format) &is_jackpot
打印名称需要一些工作，但我们可以使用Data::Dumper模块来承担部分负担。前面的内容类似：
#! /usr/bin/perl
use warnings;
use strict;
use Data::Dumper;
sub _dump {
my($ref) = @_;
local $Data::Dumper::Indent = 0;
local $Data::Dumper::Terse = 1;
scalar Dumper $ref;
}
open my $fh, "<", \$_; # get DynaLoader out of the way
my %before = %main::;
require "my.config";
my %after = %main::;
我们需要稍微不同地转储各个插槽，并在每种情况下删除引用的陷阱：
my %dump = (
SCALAR => sub {
my($ref,$name) = @_;
return unless defined $$ref;
"\$$name = " . substr _dump($ref), 1;
},
ARRAY => sub {
my($ref,$name) = @_;
return unless defined $ref;
for ("\@$name = " . _dump $ref) {
s/= \[/= (/;
s/\]$/)/;
return $_;
}
},
HASH => sub {
my($ref,$name) = @_;
return unless defined $ref;
for ("%$name = " . _dump $ref) {
s/= \{/= (/;
s/\}$/)/;
return $_;
}
},
);
最后，我们循环了%before和%after之间的集合差异：
foreach my $name (sort keys %after) {
unless (exists $before{$name}) {
no strict 'refs';
my $glob = $after{$name};
foreach my $slot (keys %dump) {
my $var = $dump{$slot}(*{$glob}{$slot},$name);
print $var, "\n" if defined $var;
}
}
}
使用问题中的my.config，输出为
$ ./prog.pl
@A = ('a','b','c')
%B = ('b' => 'bee')
$C = 'see'
答案 1 :(得分：3)
从5.010开始，您可以使用B内省模块区分是否存在SCALAR;见Detecting declared package variables in perl
更新：从该答案复制的示例：
# package main;
our $f;
sub f {}
sub g {}
use B;
use 5.010;
if ( ${ B::svref_2object(\*f)->SV } ) {
say "f: Thar be a scalar tharrr!";
}
if ( ${ B::svref_2object(\*g)->SV } ) {
say "g: Thar be a scalar tharrr!";
}
1;
答案 2 :(得分：3)
使用CPAN模块工作代码，使得一些头发不受影响Package::Stash。正如我对gbacon的回答所述，这对配置文件执行$someval = undef是盲目的，但这似乎是不可避免的，并且至少其他情况被捕获。它还限制了SCALAR，ARRAY，HASH，CODE和IO类型 - 获得GLOB和FORMAT是可能的，但它使代码不那么漂亮并且还在输出中产生噪声：）
#!perl
use strict;
use warnings;
use Package::Stash;
sub all_vars_in {
my ($package) = @_;
my @ret;
my $stash = Package::Stash->new($package);
for my $sym ($stash->list_all_package_symbols) {
for my $sigil (qw($ @ % &), '') {
my $fullsym = "$sigil$sym";
push @ret, $fullsym if $stash->has_package_symbol($fullsym);
}
}
@ret;
}
my %before;
$before{$_} ++ for all_vars_in('main');
require "my.config";
for my $var (all_vars_in('main')) {
print "$var\n" unless exists $before{$var};
}
答案 3 :(得分：1)
更新：
gbacon是对的。 * glob {SCALAR}已定义。
以下是我使用您的代码获得的输出：
Name "main::glob" used only once:
possible typo at
test_glob_foo_thing.pl line 13.
'FOO1' (SCALAR)
'FOO1' (GLOB)
'FOO2' (SCALAR)
'FOO2' (GLOB)
'_<my.config' (SCALAR)
'_<my.config' (GLOB)
尽管FOO2被定义为散列，但不是标量。
原始回答：
如果我理解正确，您只需使用内置的defined。
#!/usr/bin/env perl
use strict;
use warnings;
my %before = %main::;
require "/path/to/my.config";
my %after = %main::;
foreach my $key (sort keys %after) {
if (not exists $before{$key}) {
if(defined($after{$key}){
my $val = $after{$key};
my $what = ref($val);
print "'$key' ($what)\n";
}
}
}
答案 4 :(得分：1)
我讨厌问，但为什么不切换到真正的配置格式，而不是乱搞typeglobs？例如查看Config::Simple和YAML。
我不建议在正常情况下使用typeglobs和符号表（一些CPAN模块会这样做，但仅限于大型系统的底层 - 例如，Class :: MOP的最低级别中的Moose）。 Perl为你提供了很多可以使用的绳索，但如果你不小心的话，那根绳子也非常乐意自我否定和自我束缚：）
答案 5 :(得分：1)
no strict 'refs';
my $func_name = 'myfunc';
*{$func_name}{CODE}()
use strict 'refs';
答案 6 :(得分：0)
如果您不介意解析Data :: Dump输出，可以使用它来梳理差异。
use strict;
use warnings;
use Data::Dump qw{ dump };
my %before = %main::;
require "my.config";
my %after = %main::;
foreach my $key ( sort keys %after ) {
if ( not exists $before{$key} ) {
my $glob = $after{$key};
print "'$key' " . dump( $glob) . "\n";
}
}
将此代码与以下配置文件一起使用：
$FOO1 = 3;
$FOO2 = 'my_scalar';
%FOO2 = ( a=>'b', c=>'d' );
@FOO3 = ( 1 .. 5);
$FOO4 = [ 1 .. 5 ];
我相信这个输出提供了足够的信息，可以找出每个类型glob的哪些部分被定义：
'FOO1' do {
my $a = *main::FOO1;
$a = \3;
$a;
}
'FOO2' do {
my $a = *main::FOO2;
$a = \"my_scalar";
$a = { a => "b", c => "d" };
$a;
}
'FOO3' do {
my $a = *main::FOO3;
$a = [1 .. 5];
$a;
}
'FOO4' do {
my $a = *main::FOO4;
$a = \[1 .. 5];
$a;
}
'_<my.config' do {
my $a = *main::_<my.config;
$a = \"my.config";
$a;
}