我在使用c函数atof（）在我的asm程序中工作时遇到了一些麻烦。我试图从键盘上读取4个数字，最终打印出他们的平均值。然而，在我能做到这一点之前，我需要将数字转换为浮点数。我坚持成功地使我的'总'变量起作用。我试过在多个地方打电话无效。
这是x86 NASM程序
; nasm -f elf -l prg2.lst prg2.asm
; gcc -o prg2 prg2.o
; ./prg2
SECTION .DATA
prompt DB 'enter a test score.', 13,10
fmt DB "%s",0
fmtf DB "%f",0
SECTION .bss
test1 resb 1000 ;reserves variable names to
test2 resb 1000 ;put stuff in
test3 resb 1000
test4 resb 1000
total resb 1000
SECTION .code
extern printf
extern scanf
extern atof
global main
main:
push ebp
mov ebp, esp
push prompt
call printf
add esp, 4 ;prompt user
push test1 ;push test1 variable
push fmt
call scanf
add esp, 8 ;store test1 variable
push prompt
call printf
add esp, 4 ;prompt user
push test2 ;push test2 variable
push fmt
call scanf
add esp, 8 ;store test2 variable
push prompt
call printf
add esp, 4 ;prompt user
push test3 ;push test3 variable
push fmt
call scanf
add esp, 8 ;store test3 variable
push prompt
call printf
add esp, 4 ;prompt user
push test4 ;push test4 variable
push fmt
call scanf
add esp, 8 ;store test4 variable
mov eax,[test1]
add eax,[test2]
add eax,[test3]
add eax,[test4]
call atof
mov [total], eax
push total
call printf ;not printing what i want,
add esp,4 ;or printing anything at all
push test1 ;printing scores for verification
call printf
add esp, 4
push test2
call printf
add esp, 4
push test3
call printf
add esp, 4
push test4
call printf
add esp, 4
mov esp, ebp
pop ebp
ret
编辑：修改后，我可以使用这些代码块将输入值转换为各自的数值
mov eax, 0 ;
add eax,[test1] ;put test1 value in eax
mov [total], eax
sub eax, '0'
add eax,[test2]
mov [total], eax
sub eax,'0'
add eax,[test3]
mov [total], eax
sub eax,'0'
add eax,[test4] ;
mov [total], eax
sub eax,'0'
push total
call printf
add esp, 4
示例运行：
./prg2b
enter a test score.
1
enter a test score.
1
enter a test score.
1
enter a test score.
1
41111
这个对我的代码的添加解决了我的问题与atof（）调用，但它只有成功，如果数字是一位数，如果总数<10
如果有人可以提示如何正确使用atof，或者如何在使用scanf的程序中正确转换为浮点数，我们将不胜感激。我是非常新的（阅读：2周的学习）到x86 asm。这是在UNIX系统上的终端中编译的
答案 0 :(得分：1)
您可以使用反引号在NASM中定义带转义序列的C文字。例如。
prompt DB `enter a test score.\n`, 0 ; Don't forget the last 0
atof需要堆栈上的内存地址，并将结果返回到FPU的寄存器ST（0）。您必须先将每个字符串转换为数字，然后才能使用它进行计算。
SECTION .data
prompt DB `Enter a test score\n`, 0
fmt DB " %s", 0
fmtf DB `Sum: %f\n`, 0
SECTION .bss
test1 resb 1000
test2 resb 1000
test3 resb 1000
test4 resb 1000
double1 resq 1 ; Reserve Quadword = Double
double2 resq 1
double3 resq 1
double4 resq 1
sum resq 1
SECTION .code
extern printf, scanf, atof
global main
main:
push ebp ; Prolog
mov ebp, esp
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push test1
push fmt ; " %s"
call scanf
add esp, (2*4) ; Pop 2 dwords
push test1
call atof
fstp qword [double1]
add esp, (1*4) ; Pop 1 dword
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push test2
push fmt ; " %s"
call scanf
add esp, (2*4) ; Pop 2 dwords
push test2
call atof
fstp qword [double2]
add esp, (1*4) ; Pop 1 dword
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push test3
push fmt ; " %s"
call scanf
add esp, (2*4) ; Pop 2 dwords
push test3
call atof
fstp qword [double3]
add esp, (1*4) ; Pop 1 dword
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push test4
push fmt ; " %s"
call scanf
add esp, (2*4) ; Pop 2 dwords
push test4
call atof
fstp qword [double4]
add esp, (1*4) ; Pop 1 dword
fld qword [double1]
fadd qword [double2]
fadd qword [double3]
fadd qword [double4]
fstp qword [sum]
push dword [sum + 4] ; Push a double in two steps
push dword [sum + 0]
push fmtf ; `result: %f\n`, 0
call printf
add esp, (3*4) ; Pop 3 dwords
mov esp, ebp ; Epilog
pop ebp
ret
您不需要atof。您可以让scanf将输入的字符串转换为格式字符串＆＃34; ％LF＆＃34;
SECTION .data
prompt DB `Enter a test score\n`, 0
fmt DB " %lf", 0 ; scanf needs 'lf' to store a double
fmtf DB `Sum: %f\n`, 0 ; printf needs only 'f' to print a double
SECTION .bss
double1 resq 1 ; Reserve Quadword = Double
double2 resq 1
double3 resq 1
double4 resq 1
sum resq 1
SECTION .code
extern printf, scanf, atof
global main
main:
push ebp ; Prolog
mov ebp, esp
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push double1
push fmt ; " %lf"
call scanf
add esp, (2*4) ; Pop 2 dwords
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push double2
push fmt ; " %lf"
call scanf
add esp, (2*4) ; Pop 2 dwords
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push double3
push fmt ; " %lf"
call scanf
add esp, (2*4) ; Pop 2 dwords
push prompt ; `enter a test score\n`
call printf
add esp, (1*4) ; Pop 1 dword
push double4
push fmt ; " %lf"
call scanf
add esp, (2*4) ; Pop 2 dwords
fld qword [double1]
fadd qword [double2]
fadd qword [double3]
fadd qword [double4]
fstp qword [sum]
push dword [sum + 4] ; Push a double in two steps
push dword [sum + 0]
push fmtf ; `result: %f\n`, 0
call printf
add esp, (3*4) ; Pop 3 dwords
mov esp, ebp ; Epilog
pop ebp
ret