Question

我正在尝试修改某个目录下所有目录的编译器标志（即递归地为所有当前目录子目录及其所有子目录）。所以我发现here有两种方式：

add_directory(dir1)
# ...
add_directory(dirN)

add_compile_options(flag1 flag2 ...)
# or for CMake versions < 3.0 to do something more like:
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} flag1 flag2 ...")

add_compile_options的手册页非常清楚地说明效果将是＆＃34;当前目录及以下＆＃34; （这就是我想要的）但对set(CMAKE_CXX_FLAGS ...)我不太确定。

Cmake是否设置变量递归？

Answer 1

简短的回答是，每个子目录都有自己的变量范围，并在add_subdirectory()调用时使用当前变量值的副本进行初始化。

如需长篇答案，请参阅What's the CMake syntax to set and use variables?

目录＆amp;目标属性vs（全局）变量

CMake处理add_compile_options()和CMAKE_CXX_FLAGS的方式有所不同：

您使用add_compile_options()指定的所有内容都会附加到COMPILE_OPTIONS目录属性中。然后＆＃34;此属性用于在创建目标时初始化COMPILE_OPTIONS目标属性＆＃34;使用add_library()或add_executable()。

当解析器进行add_subdirectory()调用时，目录属性的当前状态用于初始化子目录属性。
CMAKE_CXX_FLAGS是一个全局缓存变量。您可以通过定义本地目录作用域变量（隐藏全局缓存的变量）来扩展/覆盖它。

将这些变量的上下文复制到add_subdirectory()上的子目录范围内（传播到子目录）。

并且CMake在每个CMakeLists.txt文件的 end 中查看其值并将其应用于同一CMakeLists.txt中的所有目标（允许延迟声明，另请参阅< em>下面的完整公式和测试代码。
因此对于CMake版本＆lt;相当于add_compile_options()的3.0是add_definitions()。功能仍然存在，但将定义与编译选项混合是很奇怪的。所以发明了add_compile_options()。

完整的编译器标志生成器公式

在CMake的代码中（请参阅cmCommonTargetGenerator::GetFlags()，cmLocalGenerator::AddCompileOptions()和cmLocalGenerator::AddLanguageFlags()）。

此示例显示了没有导出的DEBUG构建配置库，未考虑基于特征的标记或类似CMAKE_CXX_USE_RESPONSE_FILE_FOR_INCLUDES或CMAKE_QUOTE_INCLUDE_PATHS的内容：

  CMAKE_CXX_FLAGS       // as set at the end of target's CMakeLists.txt
+ CMAKE_CXX_FLAGS_DEBUG

+ Include Directories   // pefixed with CMAKE_INCLUDE_FLAG_CXX/CMAKE_INCLUDE_SYSTEM_FLAG_CXX

    (CMAKE_INCLUDE_CURRENT_DIR) ? 
        + CMAKE_CURRENT_SOURCE_DIR + CMAKE_CURRENT_BINARY_DIR
    + CMAKE_CXX_IMPLICIT_INCLUDE_DIRECTORIES
    + Target[INCLUDE_DIRECTORIES]
    + DependingTargets[INTERFACE_INCLUDE_DIRECTORIES] 

+ Define Flags         // compiler flags given with add_definitions()
+ Target[COMPILE_FLAGS] // deprecated
    - Filtered by CMAKE_CXX_FLAG_REGEX
+ Target[COMPILE_OPTIONS]
+ DependingTargets[INTERFACE_COMPILE_OPTIONS]

测试代码

为了更好地理解这里是我的代码，用于测试编译器选项和我得到的结果：

注意：通常我会使用add_definitions()和target_compile_definitions()代替add_compile_options()和target_compile_options()来设置编译器定义，但要演示传播编译器选项I（mis-）使用-D标志。

<强>的CMakeLists.txt

cmake_minimum_required(VERSION 3.0)

project(CxxFlagsTest)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCXX_FLAG")
add_compile_options("-DCOMPILE_OPTION")

add_subdirectory(lib)

file(WRITE main.cpp "int main() { return 0; }")
add_executable(main main.cpp)
target_link_libraries(main lib)

target_compile_options(main PRIVATE "-DMAIN_COMPILE_OPTION")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DLATE_CXX_FLAG")

get_target_property(_main_compile_options main COMPILE_OPTIONS)
message(STATUS "main COMPILE_OPTIONS: ${_main_compile_options}")
get_directory_property(_root_compile_options COMPILE_OPTIONS)
message(STATUS "root COMPILE_OPTIONS: ${_root_compile_options}")
message(STATUS "root CMAKE_CXX_FLAGS: ${CMAKE_CXX_FLAGS}")

<强> LIB /的CMakeLists.txt

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DSUB_CXX_FLAG")
add_compile_options("-DSUB_COMPILE_OPTION")

file(WRITE lib.cpp "")
add_library(lib lib.cpp)

target_compile_options(lib PUBLIC "-DLIB_COMPILE_OPTION")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DLATE_SUB_CXX_FLAG")

get_target_property(_lib_compile_options lib COMPILE_OPTIONS)
message(STATUS "lib COMPILE_OPTIONS: ${_lib_compile_options}")
get_directory_property(_sub_compile_options COMPILE_OPTIONS)
message(STATUS "sub COMPILE_OPTIONS: ${_sub_compile_options}")
message(STATUS "sub CMAKE_CXX_FLAGS: ${CMAKE_CXX_FLAGS}")

会产生以下消息：

-- lib COMPILE_OPTIONS: -DCOMPILE_OPTION;-DSUB_COMPILE_OPTION;-DLIB_COMPILE_OPTION
-- sub COMPILE_OPTIONS: -DCOMPILE_OPTION;-DSUB_COMPILE_OPTION
-- sub CMAKE_CXX_FLAGS:  ... -DCXX_FLAG -DSUB_CXX_FLAG -DLATE_SUB_CXX_FLAG
-- main COMPILE_OPTIONS: -DCOMPILE_OPTION;-DMAIN_COMPILE_OPTION
-- root COMPILE_OPTIONS: -DCOMPILE_OPTION
-- root CMAKE_CXX_FLAGS:  ... -DCXX_FLAG -DLATE_CXX_FLAG

并设置了以下预处理器定义：

<强> LIB

CXX_FLAG
SUB_CXX_FLAG
LATE_SUB_CXX_FLAG
COMPILE_OPTION
SUB_COMPILE_OPTION
LIB_COMPILE_OPTION

<强> 主

CXX_FLAG
LATE_CXX_FLAG
COMPILE_OPTION
MAIN_COMPILE_OPTION
LIB_COMPILE_OPTION

这里有趣的部分是LATE CXX标志，LIB编译选项传播了链接库。

<强>参考

Cmake是否设置变量递归？

1 个答案: