Question

我有两个不同长度的数组（类型：int）。我如何在数组a中为每个数字找到最接近的数字b（以下不起作用，但可能是因为语法错误）：

int: m;
int: n;
array [1..m] of int: a;
array [1..n] of int: b;
array[1..m] of int: results;
results = [abs(a[i] - b[j])| i in 1..m, j in 1..n];
solve minimize results;
output ["Solution: ", show(results)];

Answer 1

（它总是有一个包含尽可能多的信息的完整模型，例如“m”和“n”的值以及其他已知/固定值。另外，提及错误消息一般有帮助。）

你的模型中有一些未知的东西，所以我必须猜一点。

我猜“结果”确实应该是一个决策变量，而不是你定义的数组。然后你可以写

var int: results = sum([abs(a[i] - b[j])| i in 1..m, j in 1..n]);

或

var int: results;
...
constraint results = sum([abs(a[i] - b[j])| i in 1..m, j in 1..n]);

此外，由于它只是定义了两个常数数组“a”和“b”（必须用常量值填充），因此它不是特别有趣。我假设其中至少有一个是决策变量。决策变量数组必须用“var int”声明（或更好：类似“var 1..size”，其中1..size是数组中可能值的域）。

以下是一个工作模型的示例，可能会或可能不会像您想到的那样：

int: m = 10;
int: n = 10;
array [1..m] of int: a = [1,2,3,4,5,6,7,8,9,10];
array [1..n] of var 1..10: b;
var int: results = sum([abs(a[i] - b[j])| i in 1..m, j in 1..n]);

solve minimize results;
output [
  "Solution: ", show(results),"\n",
  "a: ", show(a), "\n",
  "b: ", show(b), "\n",
  ];

更新2015-11-19：

我不确定我是否完全理解这些要求，但这是一个变体。请注意，sum循环根本不使用“b”数组，只是“a”和“results”。为了确保从“b”中选择“结果”中的值，“结果”的域只是“b”中值的集合。

int: m = 10;
int: n = 10;
array [1..m] of int: a = [1,2,3,4,5,6,7,8,9,10];
array [1..n] of int: b = [5,6,13,14,15,16,17,18,19,20];

% decision variables

% values only from b
array[1..m] of var {b[i] | i in 1..n}: results;
var int: z; % to minimize

constraint
   z >= 0 /\
   z = sum(i in 1..m) (
     sum(j in 1..m) (abs(a[i]-results[j])) 
     % (abs(a[i]-results[i])) % alternative interpretation (see below)
   )
;

solve minimize z;

output [
  "z: ", show(z), "\n",
  "results: ", show(results),"\n",
  "a: ", show(a), "\n",
  "b: ", show(b), "\n",
];

Gecode将此作为最佳解决方案：

 z: 250
 results: [5, 5, 5, 5, 5, 5, 5, 5, 5, 5]
 a: [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
 b: [5, 6, 13, 14, 15, 16, 17, 18, 19, 20]

另一个求解器（Opturion CPX）的解决方案更类似于您的变体：

 z: 250
 results: [6, 6, 5, 5, 5, 6, 6, 6, 5, 5]
 a: [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
 b: [5, 6, 13, 14, 15, 16, 17, 18, 19, 20]

请注意，两种解决方案的最佳目标值（“z”）均为250。

然而，对于要求的替代解释（来自您的评论）：

对于a中的每个元素，从b中选择一个对应的值 - 这个 value必须是a中与每个元素最接近的值。

其中“results”中的每个值仅对应具有相同索引（“i”）的“a”中的值，即

 % ...
 constraint
   z >= 0 /\
   z = sum(i in 1..m) (
      (abs(a[i]-results[i])) 
   )

 ;

然后解决方案是（Gecode）：

z: 19
results: [5, 5, 5, 5, 5, 6, 6, 6, 6, 13]
a: [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
b: [5, 6, 13, 14, 15, 16, 17, 18, 19, 20]

然后选择“结果”（13）中的最后一个值，因为它接近10（“a”中的最后一个元素）。

更新2（2015-11-20）

关于第二条评论，关于2D（不是你写的3D版本），这是一个模型。它基于上述模型的第二种解释。将其扩展到更大的尺寸只需更改尺寸和添加循环变量。

请注意，这假设 - 可能与您的原始问题相反 - “a”和“结果”的维度相同。如果不是，那么第二种解释就不是你想要的解释。此外，我更改了“a”和“b”中的值，使其更有趣。： - ）

int: m = 3;
int: n = 3;
array [1..m,1..n] of int: a = [|1,2,3|4,5,6|7,8,9|];
array [1..m,1..n] of int: b = [|5,6,13|14,15,16,|7,18,19|];

% decision variables

% values only from b
array[1..m,1..n] of var {b[i,j] | i in 1..m, j in 1..n}: results;
var int: z;

constraint
   z >= 0 /\
   z = sum(i in 1..m, j in 1..n) (
     (abs(a[i,j]-results[i,j]))
  )
;

solve minimize z;

output [  "z: ", show(z), "\n" ]
++["results:"]++
[
  if j = 1 then "\n" else " " endif ++
    show_int(2,results[i,j])
  | i in 1..m, j in 1..n
]
++["\na:"]++
[
   if j = 1 then "\n" else " " endif ++
      show_int(2,a[i,j])
   | i in 1..m, j in 1..n
]
++["\nb:"]++
[
   if j = 1 then "\n" else " " endif ++
     show_int(2,b[i,j])
    | i in 1..m, j in 1..n
];

这方面的一个最佳解决方案是：

minizinc：在arrray中找到元素

1 个答案: