Question

在我们的项目中，concepts在配置文件中定义。举个例子：

<concepts>
    <concept name="person">
        <property name="age" type="integer"/>
        ...
    </concept>
    ...
</concepts>

虽然这与SQL没什么关系，但是这个配置文件碰巧可以映射到SQL表，列，......

从这个配置文件开始，我需要做两件事：

生成SQL创建脚本（CREATE TABLE person ( ... )）。
生成可供开发人员使用的jOOQ POJO，表格......

我想在这个项目中开始使用jOOQ。 jOOQ是否支持不从现有数据库启动的任何类型的生成（SQL创建脚本及其POJO，表，...）？我查看了文档，但找不到多少。

如果没有，我正在考虑两种选择：

基于配置文件（自定义开发）生成jOOQ POJO，表格......
基于步骤1中生成的jOOQ POJO，表格......生成SQL创建脚本（自定义开发）

或

基于配置文件生成SQL创建脚本（自定义开发）
在可嵌入的数据库中执行这些脚本，例如H2或SQLite（非常简单）（虽然脚本也将在'真正的'数据库中执行，但最好在这里使用内存数据库，避免任何依赖）
基于此数据库生成jOOQ POJO，表格......（由jOOQ库提供）

虽然我认为第一个选项需要更多努力，但目前我还是有利，因为第二个选项中的第3步可能会导致信息丢失。

Answer 1

这显然可以通过XSLT来解决

生成SQL脚本：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/">
        <result>
            <xsl:apply-templates select="concepts/concept"/>
        </result>
    </xsl:template>

    <xsl:template match="concept">
        <xsl:text>CREATE TABLE </xsl:text>
        <xsl:value-of select="@name"/>
        <xsl:text>(</xsl:text>
        <xsl:apply-templates select="property"/>
        <xsl:text>
);
</xsl:text>
    </xsl:template>

    <xsl:template match="property">
        <xsl:choose>
            <xsl:when test="position() > 1">
                <xsl:text>
, </xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:text>
  </xsl:text>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:value-of select="@name"/>
        <xsl:text> </xsl:text>
        <xsl:value-of select="@type"/>
    </xsl:template>
</xsl:stylesheet>

生成jOOQ元XML

jOOQ-meta支持使用XMLDatabase

从XML导入架构元信息

<configuration>
    <generator>
        <database>
            <name>org.jooq.util.xml.XMLDatabase</name>
            <properties>
                <property>
                    <key>dialect</key>
                    <value>ORACLE</value>
                </property>
                <property>
                    <key>xml-file</key>
                    <value>src/main/resources/concepts-transformed.xml</value>
                </property>
            </properties>

只需将您的XML文件转换为以下格式： http://www.jooq.org/xsd/jooq-meta-3.5.4.xsd

...例如使用以下XSLT：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:variable name="schema" select="'MY_SCHEMA'"/>

    <xsl:template match="/">
        <information_schema xmlns="http://www.jooq.org/xsd/jooq-meta-3.5.4.xsd">
            <schemata>
                <schema>
                    <schema_name><xsl:value-of select="$schema"/></schema_name>
                </schema>
            </schemata>
            <tables>
                <xsl:apply-templates select="concepts/concept"/>
            </tables>
            <columns>
                <xsl:apply-templates select="concepts/concept/property"/>
            </columns>
        </information_schema>
    </xsl:template>

    <xsl:template match="concept">
        <table>
            <schema_name><xsl:value-of select="$schema"/></schema_name>
            <table_name><xsl:value-of select="@name"/></table_name>
        </table>
    </xsl:template>

    <xsl:template match="property">
        <column>
            <schema_name><xsl:value-of select="$schema"/></schema_name>
            <table_name><xsl:value-of select="../@name"/></table_name>
            <column_name><xsl:value-of select="@name"/></column_name>
            <data_type><xsl:value-of select="@type"/></data_type>
        </column>
    </xsl:template>
</xsl:stylesheet>

jOOQ - jOOQ是否支持定义文件或创建SQL创建脚本？

1 个答案:

生成SQL脚本：

生成jOOQ元XML