Question

我有这个由宏m1调用的递归宏m1-do。目的是生成一些函数调用。

(defmacro m1 [fname x]
  (if (= (count x) 1)
    (let [a0 (first x)]
      `(~fname ~a0))
    (let [[a0 & arest] x]
      `((~fname ~a0) (m1 ~fname ~arest)))))

(defmacro m1-do [fname x]
  `(do (m1 ~fname ~x)))

这就是我想要的结果：

(m1-do f1 (45 98 122 143 215)) =>
(do (f1 45) (f1 98) (f1 122) (f1 143) (f1 215))

但是我在每次递归时得到一个额外的括号级别。第一个结果已经有太多了：

user=> (clojure.walk/macroexpand-all '(m1-do f1 (45 98)))
(do ((f1 45) (f1 98)))
user=> (clojure.walk/macroexpand-all '(m1-do f1 (45 98 122)))
(do ((f1 45) ((f1 98) (f1 122))))
user=> (clojure.walk/macroexpand-all '(m1-do f1 (45 98 122 143)))
(do ((f1 45) ((f1 98) ((f1 122) (f1 143)))))
user=> (clojure.walk/macroexpand-all '(m1-do f1 (45 98 122 143 215)))
(do ((f1 45) ((f1 98) ((f1 122) ((f1 143) (f1 215))))))

问题似乎是每个调用返回一个列表，它添加了另一对()，我还试图开发一些flattening函数并在宏中使用它但没有成功。

这些数字只是真实内容的占位符，而且更复杂。

Answer 1

你可以用一个非常简单的非递归宏来做到这一点：

(defmacro m1-do [fname coll]
  `(do ~@(map (partial list fname) coll)))

以下是cons：

的相同方法

(defmacro m1-do [fname coll]
  (cons 'do (map (partial list fname) coll)))

两个版本完全相同并产生欲望输出：

(macroexpand '(m1-do f1 (45 98 122 143 215)))
; => (do (f1 45) (f1 98) (f1 122) (f1 143) (f1 215))

如何在Clojure中的每个宏递归上避免额外的括号级别

1 个答案: