Question

我在编写带有字符和字符列表的此函数时遇到问题，然后消除列表中最后一次出现的输入字符。我可以使用下面的函数取出输入字符的第一个出现位置：

fun :: Char -> String -> String
fun c (s:ss)
 | s == c   = ss
 | otherwise = s : fun c ss
fun _ [] = []

我需要帮助的是如何修改此函数以取出输入字符的最后一次出现，而不是第一次出现。结果应该是fun 'c' "abcdccytrc"返回"abcdccytr"。

Answer 1

好的，这就是我想出的：

fun :: Char -> String -> String
fun c (s:ss)
 | ((fun c ss) == ss) && (s == c) = ss
 | otherwise                      = s : fun c ss
fun _ [] = []

基本上，如果s == c和字符串的其余部分（ss）通过在其上运行此函数而保持不变（即，它不包含字符c），则返回剩下的人物。

如果不满足此要求（即，字符串的其余部分至少有一次字符c），请保留当前字符并将该函数应用于字符串的其余部分。 / p>

除此之外，我认为反转字符串然后调用原始函数，然后再次反转它，就像我在评论中建议的那样，可能更容易理解，但这只是意见。

Answer 2

正如Numeri建议的那样，通过删除反向列表中的第一个匹配项来删除最后一个匹配项是一种方法：

removeFirst :: Char -> String -> String
removeFirst _ [] = []
removeFirst c1 (c2:cs) = if c1 == c2 then cs else c2:removeFirst c1 cs

removeLast :: Char -> String -> String
removeLast c1 = reverse . removeFirst c1 . reverse

正如Will Ness建议的那样，返回删除最后一个匹配项的字符串，以及指示是否应该删除当前事件的布尔值，是另一个：

removeLast :: Char -> String -> String
removeLast c1 = snd . remLast
  where
    remLast :: String -> (Bool, String)
    remLast [] = (False, [])
    remLast (c2:cs) =
      case remLast cs of
        (True, cs') -> (True, c2:cs')
        (False, cs') -> if c1 == c2 then (True, cs') else (False, c2:cs')

取出最后一次输入字符的Haskell函数

2 个答案: