Question

我必须创建一个程序，当用户按下进入或退出时，将给定的用户输入（十进制）转换为二进制匹配。任何人都可以指定如何开始此分配。我们需要使用掩码和循环，但我不知道从哪里开始。

Answer 1

我写了这个，因为没有很多二进制掩码的例子。

二进制掩码在汇编中很有用，因为它使我们能够检查十进制或十六进制值中的单个位。

实施例：如果我们查看十进制数 5 ，我们知道它的二进制值是 0101 ，当我们在第一个循环上AND R4, R4, R5时，我们比较 1000 0101 。由于 bit [3] 在 0101 中为零，我们告诉LC3模拟器打印出一个ASCII字符＆＃34; 0＆＃34;。然后，我们使用下一个二进制掩码 0100 重复该过程。

这可能是一个棘手的概念，所以我首先看一下循环和位掩码的几个例子。

LC3 Bit Counter

How do I write a program that prints out “Hello World”, 5 times using a loop in LC3?

.ORIG x3000

    LEA R0, PROMPT
    PUTs                ; TRAP x22
    LD R0, ENTER
    OUT                 ; TRAP x21
    IN                  ; TRAP x23

    AND R5, R5, #0      ; clear R5
    ADD R5, R5, R0      ; Store the user input into R5

    AND R1, R1, #0      ; clear R1, R1 is our loop count
    LD R2, MASK_COUNT   ; load our mask limit into R2
    NOT R2, R2          ; Invert the bits in R2
    ADD R2, R2, #1      ; because of 2's compliment we have
                        ; to add 1 to R2 to get -4
WHILE_LOOP
    ADD R3, R1, R2      ; Adding R1, and R2 to see if they'll
                        ; will equal zero
    BRz LOOP_END        ; If R1+R2=0 then we've looped 4
                        ; times and need to exit

    LEA R3, BINARY      ; load the first memory location 
                        ; in our binary mask array
    ADD R3, R3, R1      ; use R1 as our array index and
                        ; add that to the first array location
    LDR R4, R3, #0      ; load the next binary mask into R4

    AND R4, R4, R5      ; AND the user input with the 
                        ; binary mask
    BRz NO_BIT
    LD R0, ASCII_ONE
    OUT                 ; TRAP x21
    ADD R1, R1, #1      ; add one to our loop counter
    BRnzp WHILE_LOOP    ; loop again
NO_BIT
    LD R0, ASCII_ZERO
    OUT                 ; TRAP x21

    ADD R1, R1, #1      ; add one to our loop counter
    BRnzp WHILE_LOOP    ; loop again
LOOP_END

    LD R0, ENTER
    OUT                 ; TRAP x21
    HALT                ; TRAP x25

; Binary Maps
BINARY  .FILL   b0000000000001000
        .FILL   b0000000000000100
        .FILL   b0000000000000010
        .FILL   b0000000000000001
        .FILL   b0000000000000000

; Stored Values
ENTER       .FILL   x000A
ASCII_ZERO  .FILL   x0030
ASCII_ONE   .FILL   x0031
MASK_COUNT  .FILL   x04     ; loop limit = 4
PROMPT      .STRINGZ "Enter a number from 0-9"

.END

LC-3十进制到二进制转换器

1 个答案: