Question

在R2和R3中，我可以使用unique删除系列中的重复项：

>> a: [1 2 2 3]
>> length? a
== 4
>> length? unique a
== 3

如何对一系列对象执行相同的操作？如，

b: reduce [
    make object! [a: 1] 
    make object! [b: 2] 
    make object! [b: 2] 
    make object! [c: 3]
]
>> length? b
== 4
>> length? unique b
== 4  ; (I'd like it to be 3)

Answer 1

UNIQUE和其他集合操作中的相等性检查的实现似乎是Cmp_Value，并且比较的方式是减去对象的帧指针。如果该减法为零（例如，这些是SAME？对象），那么比较被认为是匹配：

f-series.c Line 283, R3-Alpha open source release

如果查看周围的代码，您会在同一例程中看到对Cmp_Block的调用。在Cmp_Block的情况下，它进行递归比较，并尊重区分大小写...因此块和对象之间的区别如下：

Cmp_Block() in f-series.c

鉴于它是以这种方式编写的，如果您希望UNIQUE操作基于对象与其身份的逐场比较，除了编写您自己的例程之外，没有办法做到这一点并调用EQUAL？...或修改C代码。

这是一个不需要更改C源的短暂黑客，它在UNIQUE的输出上执行MAP-EACH。身体过滤掉任何EQUAL？已经看到的对象（因为当MAP-EACH的主体返回未设置时，它不会对结果添加任何内容）：

my-unique: function [array [block!]] [
    objs: copy []
    map-each item unique array [
        if object? :item [
            foreach obj objs [
                if equal? item obj [unset 'item break]
            ]
            unless unset? :item [append objs item]
        ]
        :item ;-- if unset, map-each adds nothing to result
    ]
]

不幸的是你必须使用BLOCK！而不是MAP！随着时间跟踪物体，因为MAP！目前不允许将对象作为键。如果他们允许它，他们可能会遇到相同的问题，即不使用相同的对象进行散列。

（注意：修复此问题和其他问题是Ren-C分支的雷达，除了现在是fundamental fixes最快的Rebol解释器之外，还有一点{{3 enhancements to the set operations）

中的讨论

Answer 2

EQUAL？和相同？仅当对象是相同的对象引用时才返回true。我编写了一个函数来检查对象之间的相似性，如果两个对象具有相同的值且具有相同类型的相同单词，则返回true：

similar?: func [
    {Returns true if both object has same words in same types.}
    o [object!] p [object!] /local test
][
    test: [if not equal? type? get in o word type? get in p word [return false]]
    foreach word sort first o test
    foreach word sort first p test
    true
]

您可以按以下方式进行测试：

>> o: make object! [b: 2]
>> p: make object! [b: 2]
>> equal? o p
== false
>> same? o p
== false
>> similar? o p
== true

您可以在您的情况下使用它。

Answer 3

unique+: func [array [block!]] [
    objs: copy []
    map-each item unique array [
        if object? :item [
            foreach obj objs [
                if equal-object? :item :obj [unset 'item break]
            ]
            if value? 'item [append objs item]
        ]
        ;-- If unset, map-each adds nothing to result under R3.
        ;   R2 behaves differently. This works for both.
        either value? 'item [:item] [()]
    ]
]

equal-object?: func [
    "Returns true if both objects have same words and values."
    o [object!] p [object!]
][
    if not equal? sort words-of o sort words-of p [return false]
    foreach word words-of o [
        if not equal? o/:word p/:word [return false]
    ]
    true
]

从Rebol中的系列中删除重复的对象

3 个答案: