Question

我试图执行以下操作：

bmp := TBitmap.Create;
bmp.Width := FWidth;
bmp.Height := FHeight;
for y := 0 to FHeight - 1 do
begin
   sl := bmp.ScanLine[y];
   for x := 0 to FWidth - 1 do
   begin
      //draw to the scanline, one pixel at a time
   end;
end;
//display the image
bmp.Free;

不幸的是，我最终得到的图像是完全白色的图像，除了底线，它被适当地着色。一些调试显示，每次我访问ScanLine属性时，它都会调用TBitmap.FreeImage，然后进入if (FHandle <> 0) and (FHandle <> FDIBHandle) then块，这会重置整个图像，所以只有实际上最后一行的更改。

在我目前使用TBitmap.ScanLine看到的每个演示中，他们都是从加载图片开始的。（显然，这会正确地设置各种手柄，以便最终不会发生这种情况？）但我并没有尝试加载图像并对其进行处理;我试图从相机中捕捉图像数据。

如何设置位图，以便我可以在不必先加载图像的情况下绘制到扫描线？

Answer 1

在开始绘制之前，您应该明确设置PixelFormat。例如，

procedure TForm1.FormPaint(Sender: TObject);
var
  bm: TBitmap;
  y: Integer;
  sl: PRGBQuad;
  x: Integer;
begin

  bm := TBitmap.Create;
  try
    bm.SetSize(1024, 1024);
    bm.PixelFormat := pf32bit;
    for y := 0 to bm.Height - 1 do
    begin
      sl := bm.ScanLine[y];
      for x := 0 to bm.Width - 1 do
      begin
        sl.rgbBlue := 255 * x div bm.Width;
        sl.rgbRed := 255 * y div bm.Height;
        sl.rgbGreen := 255 * x div bm.Width;
        inc(sl);
      end;
    end;

    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;

end;

如何在不加载图像的情况下使用扫描线进行绘制？

1 个答案: