Question

我是xml xslt transofrmation的新手。请帮我一个小样本来了解。我想要： 1）将xml转换为csv 2）第一个字符串必须包含列名 3）仅转换字段：name，state，records \ record（仅获取记录列表中的最后一条记录）

我也有xslt代码，但我无法根据我的要求修改此代码。请帮我修改代码。

CSV

name, state, record 
"Shockwave", "New", "3"
"Other", " Canceled ", "7"

xml

<projects>
  <project>
   <name>Shockwave</name> 
   <language>Ruby</language> 
   <owner>Brian May</owner> 
   <state>New</state> 
   <startDate>31/10/2008 0:00:00</startDate> 
   <records>
      <record>1</records>
      <record>5</records>
      <record>3</records>
   </records>
  </project>
  <project>
   <name>Other</name> 
   <language>Erlang</language> 
   <owner>Takashi Miike</owner> 
   <state> Canceled </state> 
   <startDate>07/11/2008 0:00:00</startDate> 
   <records>
      <record>5</records>
      <record>6</records>
      <record>7</records>
   </records>
  </project>
</projects>



<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" encoding="utf-8" />

  <xsl:param name="delim" select="','" />
  <xsl:param name="quote" select="'&quot;'" />
  <xsl:param name="break" select="'&#xA;'" />

  <xsl:template match="/">
    <xsl:apply-templates select="projects/project" />
  </xsl:template>

  <xsl:template match="project">
    <xsl:apply-templates />
    <xsl:if test="following-sibling::*">
      <xsl:value-of select="$break" />
    </xsl:if>
  </xsl:template>

  <xsl:template match="*">
    <!-- remove normalize-space() if you want keep white-space at it is --> 
    <xsl:value-of select="concat($quote, normalize-space(), $quote)" />
    <xsl:if test="following-sibling::*">
      <xsl:value-of select="$delim" />
    </xsl:if>
  </xsl:template>

  <xsl:template match="text()" />
</xsl:stylesheet>

Answer 1

我认为你需要做的更复杂。试试这种方式：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="utf-8" />

<xsl:template match="/projects">
    <xsl:text>name, state, record&#10;</xsl:text>
    <xsl:for-each select="project">
        <xsl:value-of select="concat('&quot;', name, '&quot;')" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="concat('&quot;', state, '&quot;')" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="concat('&quot;', records/record[last()], '&quot;')" />
        <xsl:if test="position()!=last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

请注意，这假设所涉及的字段都不包含引号。

加了：

你可以修改你的xslt文件并添加函数替换单引号两个双倍的字段值＆＃34;名称＆＃34;？

将此模板添加到样式表中：

<xsl:template name="replace">
    <xsl:param name="text"/>
    <xsl:param name="searchString">"</xsl:param>
    <xsl:param name="replaceString">""</xsl:param>
    <xsl:choose>
        <xsl:when test="contains($text,$searchString)">
            <xsl:value-of select="substring-before($text,$searchString)"/>
            <xsl:value-of select="$replaceString"/>
            <xsl:call-template name="replace">
                <xsl:with-param name="text" select="substring-after($text,$searchString)"/>
                <xsl:with-param name="searchString" select="$searchString"/>
                <xsl:with-param name="replaceString" select="$replaceString"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

并改变这一点：

        <xsl:value-of select="concat('&quot;', name, '&quot;')" />
        <xsl:text>, </xsl:text>

为：

        <xsl:text>"</xsl:text>
        <xsl:call-template name="replace">
            <xsl:with-param name="text" select="name"/>
        </xsl:call-template>
        <xsl:text>",</xsl:text>

如何在将xml转换为csv时仅选择所需的字段和值

1 个答案:

加了：