Question

我有一个gradle任务，它调用脚本并使用-PARGS将命令行参数传递给脚本。

task taskAll(type: Exec, dependsOn: taskinit) {
    environment['PROJECT_ROOT'] = "${projectDir}"
    workingDir rootProject.projectDir.path
    description = 'Main task'

    executable rootProject.projectDir.path + "/execute.me"
    if (project.hasProperty('ARGS')) {
        args(ARGS.split(','))
    }
}

我使用以下任何选项调用此gradle任务

./gradlew taskAll
./gradlew taskAll -PARGS="arg1"
./gradlew taskAll -PARGS="arg2"

但是，我想看看是否将taskAll分成多个任务，比如说

./gradlew taskA    #Calls task taskAll with arg1
./gradlew taskB    #Calls task taskAll with arg2

我知道我必须复制taskAll来创建taskA，taskB并删除每个中的“if”条件和硬编码args。

但是，我想知道是否可以通过让MainTask只调用可执行文件来实现更清晰的实现，然后让TaskA，TaskB，TaskC调用{{1}并传递参数MainTask，arg1和arg2。

Answer 1

在大多数情况下，通过提供dependsOn和可选的mustRunAfter属性，通过配置任务依赖性来完成从另一个任务执行一个任务。在您的情况下，它无法使用它，因为您的主要任务必须在执行某些配置任务后执行。在这种情况下，您可以使用任务的finalizedBy属性。

根据您的要求，您可以创建许多任务，这些任务将根据您的需要设置一些带有预定义参数的脚本变量。而且你可以离开你的主要任务，它将依赖于这些论点来调用某些东西。您唯一需要做的就是让每个自定义任务都成为您的主要任务。因此，每次调用自定义任务都会在执行后执行主任务。

这是一个简短的例子，如何做到：

//define a variable to store arguments
def ARGS = null

//2 custom tasks, which set arguments during the execution phase
task taskA << {
    ARGS = "poperty1,property2"
}

task taskB << {
    ARGS = "property3,property4"
}

//your main task
task mainTask (type: Exec) {
    environment['PROJECT_ROOT'] = "${projectDir}"
    workingDir rootProject.projectDir.path
    description = 'Main task'

    executable rootProject.projectDir.path + "/execute.me"

    //here is the main difference, we moved arguments setting into 
    //execution phase, before execution of this task
    doFirst{
        //if you call custom task it will be executed with predefined params
        if (ARGS != null) {
            args(ARGS)
        //if you call mainTask, you are able to pass arguments via command line with -PCOMMAND_LINE_ARGS=123
        } else if (project.hasProperty('COMMAND_LINE_ARGS')) {
            args(COMMAND_LINE_ARGS)
        } else {
            throw new GradleException("No arguments found")
        }
    }
}

//finilization settings for custom tasks
taskA.finalizedBy mainTask
taskB.finalizedBy mainTask

Answer 2

您可以使用ext：

task outraTask << {
    printf(arg0)
    printf(arg1)
}

project(':projetc2').tasks.outraTask {
    ext.arg0 = "0"
    ext.arg1 = "1"
}.execute()

输出：

> Task :projetc2:outraTask
0
1

使用参数从另一个调用一个Gradle Task

2 个答案: