Question

我正在尝试创建一个用于在方案中使用R5RS语言展平列表的函数，并且遇到了我的函数只返回输入列表而不删除括号的问题。我认为这是由于额外的缺点，但当我删除它时，输出变为列表，没有括号中的元素。有人能指出我正确的方向吗？

(define (denestify lst)
  (cond ((null? lst)'())
        ((list? (car lst))(cons (denestify (cons (car (car lst))(cdr (car lst))))
                                (denestify (cdr lst))))
        (else (cons (car lst)(denestify (cdr lst))))))

Answer 1

这显示了如何将ÓscarLópez的答案转换为不使用append并且也是尾递归的答案：

(define (denestify-helper lst acc stk)
  (cond ((null? lst) 
         (if (null? stk) (reverse acc)
             (denestify-helper (car stk) acc (cdr stk))))
        ((pair? (car lst))
         (denestify-helper (car lst) acc (cons (cdr lst) stk)))
        (else 
         (denestify-helper (cdr lst) (cons (car lst) acc) stk))))

(define (denestify lst) (denestify-helper lst '() '()))

(denestify '(1 (2 (3 4 (5) (6 (7) (8)) (9))) 10))

请注意它如何使用累加器以反向方式构建列表，并将列表另存为堆栈。

结果是

'(1 2 3 4 5 6 7 8 9 10)

正如所料。

发布后我想到了这个改变：

(define (denestify-helper lst acc stk)
  (cond ((null? lst) 
         (if (null? stk) (reverse acc)
             (denestify-helper (car stk) acc (cdr stk))))
        ((pair? (car lst))
         (denestify-helper (car lst) acc (if (null? (cdr lst)) 
                                             stk 
                                             (cons (cdr lst) stk))))
        (else 
         (denestify-helper (cdr lst) (cons (car lst) acc) stk))))

通过在堆栈上有效地进行尾调用优化，消除了一些无用的cons。可以进一步优化处理一个元素列表。

Answer 2

如果您要展平列表列表，则必须使用append来合并每个子列表。此外，您的实现过于复杂，请尝试这样做：

(define (denestify lst)
  (cond ((null? lst) '())
        ((pair? (car lst))
         (append (denestify (car lst))
                 (denestify (cdr lst))))
        (else (cons (car lst) (denestify (cdr lst))))))

例如：

(denestify '(1 (2 (3 4 (5) (6 (7) (8)) (9))) 10))
=> '(1 2 3 4 5 6 7 8 9 10)

在计划中展平列表

2 个答案: