Question

Windows命令行中是否有办法以标准化的与语言环境无关的格式检索文件或目录的日期/时间戳（修改，创建，访问）（例如，{{ 3}}）？

我发现dir的输出使用了系统相关的日期/时间格式，缺少秒数对于参数~t）和%~t1变量展开（for）的%~tI修饰符也是如此。此外，forfiles变量@fdate和@ftime取决于系统设置（尽管后者至少还返回秒数）。

我了解到wmic OS GET LocalDateTime /VALUE是一种获取当前系统日期/时间的方法（输出可能看起来像LocalDateTime=20151021020000.000000+120，它可以被{{1}捕获}}）。
但是还有一个命令（行）以类似的格式返回文件或目录日期/时间戳吗？

Answer 1

Here您可以找到获取文件时间的方法。

1）对于目录，您可以使用 WMIC 查询：

@echo off
set "directory=."

for /f "delims=" %%# in ("%directory%") do set "directory=%%#"

set "directory=%temp%"
for /f "usebackq delims=" %%# in (`"WMIC path Win32_Directory WHERE name='%directory:\=\\%' get creationdate,LastAccessed,LastModified /format:value"`) do (
  for /f %%@ in ("%%#") do echo %%@
)

2）或使用 jscript hybrid （就像您可以使用的文件版本LastModified，CreationDate或LastAccessed一样）：

@if (@X)==(@Y) @end /****** jscript comment ******
@echo off

set "directory=."
for %%# in (%directory%) do set "directory=%%~f#"
if exist "%directory%\" (

 cscript //E:JScript //nologo "%~f0" "%directory%"
)
exit /b %errorlevel%

****** end of jscript comment ******/

var file_loc = WScript.Arguments.Item(0);
var fso = new ActiveXObject("Scripting.FileSystemObject");
var the_file=fso.GetFolder(file_loc);
var the_date= new Date(the_file.DateLastModified);
WScript.Echo(the_date.getFullYear());
WScript.Echo(the_date.getMonth());
WScript.Echo(the_date.getUTCDate());

3）使用自编译的jscript.net （由于.NET格式化功能，这可能是最强大的选项）：

@if (@X)==(@Y) @end /****** start of jscript comment ******

@echo off
::::::::::::::::::::::::::::::::::::
:::       compile the script    ::::
::::::::::::::::::::::::::::::::::::
setlocal
if exist "%~n0.exe" goto :skip_compilation

set "frm=%SystemRoot%\Microsoft.NET\Framework\"
:: searching the latest installed .net framework
for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
    if exist "%%v\jsc.exe" (
        rem :: the javascript.net compiler
        set "jsc=%%~dpsnfxv\jsc.exe"
        goto :break_loop
    )
)
echo jsc.exe not found && exit /b 0
:break_loop


call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
::::::::::::::::::::::::::::::::::::
:::       end of compilation    ::::
::::::::::::::::::::::::::::::::::::
:skip_compilation



set "directory=."
for %%# in (%directory%) do set "directory=%%~f#"


"%~n0.exe" "%directory%"


exit /b 0


****** end of jscript comment ******/
import System;
import System.IO;

var arguments:String[] = Environment.GetCommandLineArgs();

var the_dir=arguments[1];

var last_modified=Directory.GetLastWriteTime(the_dir);
Console.WriteLine("modified time "+last_modified.ToString("yyyy-MM-dd"));

var created=Directory.GetCreationTime(the_dir);
Console.WriteLine("created time "+created.ToString("yyyy-MM-dd"));

var accessed=Directory.GetLastAccessTime(the_dir);
Console.WriteLine("accessed time "+accessed.ToString("yyyy-MM-dd"));

编辑以下是使用所有列出方法的参数化脚本的准备工作：

fileModifiedTime.bat - 获取具有独立设置格式的文件的上次修改时间。基于 robocopy
fileTimes.bat - 获取 WMIC
dirTimes.bat - 获取 WMIC
fileTimesJS.bat - 使用 jscript
dirTimesJS.bat - 使用 jscript
fileTimesNET.bat - 使用 .NET
dirTimesNET.bat - 带有 .NET

如何获得文件或目录的标准化日期/时间戳。在纯批处理脚本？

1 个答案: