Hadoop Pig：使用STARTSWITH显示条目

Question

我在使用STARTSWITH字符串函数时遇到问题。我想显示System_Period中以20040开头的所有记录

transactions = LOAD '/home/cloudera/datasets/assignment2/Transactions.csv'
USING PigStorage(',') AS (Branch_Number:int, Contract_Number:int,
Customer_Number:int,Invoice_Date:chararray, Invoice_Number:int,
Product_Number:int, Sales_Amount:double, Employee_Number:int,
Service_Date:chararray, System_Period:int);

sysGroup = GROUP transactions BY System_Period;

sysFilter = FILTER sysGroup BY STARTSWITH(transactions.System_Period, 20040);

DUMP sysFilter;

我收到的错误是

Could not infer the matching function for org.apache.pig.builtin.STARTSWITH as multiple or none of them fit. Please use an explicit cast.

Answer 1

STARTSWITH仅用于比较tuple1和tuple2以检查tuple1是否包含tuple2。你无法传递关系或包。还有一点需要注意的是它只接受String（chararray）而不是整数。在GROUP BY之前过滤以20040开头的system_period，并将system_period加载为chararray，然后根据需要将其转换为过滤器。

transactions = LOAD '/home/cloudera/datasets/assignment2/Transactions.csv'
USING PigStorage(',') AS (Branch_Number:int, Contract_Number:int,
Customer_Number:int,Invoice_Date:chararray, Invoice_Number:int,
Product_Number:int, Sales_Amount:double, Employee_Number:int,
Service_Date:chararray, System_Period:chararray);
sysFilter = FILTER transactions BY STARTSWITH(System_Period, '20040');

在GROUP BY FLATTEN结果后再过滤

transactions = LOAD '/home/cloudera/datasets/assignment2/Transactions.csv'
USING PigStorage(',') AS (Branch_Number:int, Contract_Number:int,
Customer_Number:int,Invoice_Date:chararray, Invoice_Number:int,
Product_Number:int, Sales_Amount:double, Employee_Number:int,
Service_Date:chararray, System_Period:chararray);
sysGroup = GROUP transactions BY System_Period;
flatres = FOREACH sysGroup GENERATE group,FLATTEN(transactions);
sysFilter = FILTER flatres BY STARTSWITH(System_Period, '20040');