Question

我正在使用XML::Simple和XML::Dumper。我很清楚前一个模块的问题。如果我可以使用替代库，我会。

我想要实现的是加载XML，然后为其添加行。这是脚本运行之前的XML结构。

<person>
  <appearance>
     <param name="height" value="6,3"/>
  </appearence>
</person>

脚本或我打算编码的内容应该从文件加载此XML，然后将<param>元素附加到<appearence>。我尝试使用此代码：

use warnings;

use XML::Simple;
use XML::Dumper;

my $xml = XMLin('xml_import.xml');

$xml->{appearence} .= qq{<param name="age" value="22" />};
my $new_xml = XMLout($xml, noattr => 1, NoEscape => 1);

open(FILE, ">xml_import.xml");
print FILE $new_xml;
close FILE;

不幸的是输出是这样的：

<opt>
  <appearence>HASH(0x1722190)<param name="age" value="22" /></appearence>
</opt>

我不仅将原始的<person>代码丢失到<opt>，而且HASH字符串取代了我认为现有的<param>元素。我已经阅读了XML::Simple的文档，但我无法确定应该使用什么参数来防止这种情况发生。

Answer 1

使用XML::Simple的关键是使用Perl数据结构，而不是代码中的XML。

您的问题确切地说明了为什么不鼓励使用该模块。您必须使用ForceArray才能轻松更改父级中元素的数量，并且必须清除KeyAttr以阻止对name属性的特殊处理。

#!/usr/bin/perl
use warnings;
use strict;

use XML::Simple;

my $xml = << '__XML__';
<person>
  <appearance>
     <param name="height" value="6,3"/>
  </appearance>
</person>
__XML__

my $simple = XMLin($xml, ForceArray => 1,
                         KeepRoot   => 1,
                         KeyAttr    => [],
                  );

push @{ $simple->{person}[0]{appearance}[0]{param} }, { name  => 'age',
                                                        value => 22,
                                                      };
print XMLout($simple, KeepRoot => 1);

为了进行比较，XML::XSH2中的相同任务是XML::LibXML的包装：

open file.xml ;
my $p := insert element param append /person/appearance ;
set $p/@name 'age' ;
set $p/@value 22 ;
save :b ;

Answer 2

1.丢失标签的原因是“XMLin（）通常会丢弃根元素名称。将'KeepRoot'选项设置为'1'将导致保留根元素名称。”

2.从文件中读取xml后，应将变量作为perl数据结构运行。

#! /usr/bin/perl

use strict;
use XML::Simple qw(:strict);
use Data::Dumper;

my $xml = XMLin('xml_import.xml', KeepRoot => 1, KeyAttr => ["param"], ForceArray => ["param"]);
print '-----$xml-----', "\n", Dumper($xml), "\n";

my $new_node = {'name' => 'age', 'value' => '22'};
push $xml->{person}->{appearance}->{param}, $new_node;
print '-----Insert a new node to $xml-----', "\n", Dumper($xml), "\n";

my $new_xml = XMLout($xml, NoAttr => 1, NoEscape => 1, KeepRoot => 1, KeyAttr => []);
print '-----$new_xml-----', "\n", $new_xml, "\n";

或者

#! /usr/bin/perl

use strict;
use XML::Simple qw(:strict);
use Data::Dumper;

my $xml = XMLin('xml_import.xml', KeepRoot => 1, KeyAttr => {param => "+name"}, ForceArray => ["param"]);
print '-----$xml-----', "\n", Dumper($xml), "\n";

my $new_node = {'name' => 'age', 'value' => '22'};
$xml->{person}->{appearance}->{param}->{age} = $new_node;
print '-----Insert a new node to $xml-----', "\n", Dumper($xml), "\n";

my $new_xml = XMLout($xml, NoAttr => 1, NoEscape => 1, KeepRoot => 1, KeyAttr => {param => "+name"});
print '-----$new_xml-----', "\n", $new_xml, "\n";

解析XML数据并使用XML :: Simple附加新元素

2 个答案: