Question

我有一个带有约束类型参数的方法，我希望它能够在x和y类型为Float的任何对象上使用：

public static function nearest<T:{var x:Float; var y:Float;}>
(x1:Float, y1:Float, objs:Array<T>, distanceMetric:Float->Float->Float->Float->Float):T { 
    // Snip. Returns the object nearest to x1,y1
}

问题在于，当提供的x上的y和/或T是带有getter或setter的属性时，类型约束检查失败，导致错误，如：

最近的约束检查失败.T

字段x的不一致访问：（get，set）应为（默认，默认）

我认为处理类字段和属性是很好的，就像编写泛型算法一样。如果使用类型约束不可能，那么有没有办法可以使用Haxe 3.2？

Answer 1

扩展@clemos'的答案 - 无法处理类字段和属性，就像它们与简单的typedef一样，因为Haxe getter和setter在编译时被解析 - 有另一种方法可以解决这个问题。

然而，这有点麻烦。您可以在行动here中看到它。

首先，我们在一个包含变量和属性的包装器上构建一个抽象：

// let's start with our possible point types
typedef NoGetters = { x:Float, y:Float };
typedef WithProperties = { var x(get,set):Float; var y(get,set):Float; };

// now, let's prepare a common implementation for them
typedef SomePoint2Impl<T> = { obj:T, get_x:Void->Float, get_y:Void->Float };
// and use it in and abstract
abstract SomePoint2<T>(SomePoint2Impl<T>) from SomePoint2Impl<T> {
    // these wrap points in the common type
    @:from static function fromNoGetters<T:NoGetters>(p:T):SomePoint2<T>
        return { obj : p, get_x : function () return p.x, get_y : function () return p.y };
    @:from static function fromWithProperties<T:WithProperties>(p:T):SomePoint2<T>
        return { obj : p, get_x : function () return p.x, get_y : function () return p.y };

    // and this restores the original type from the common one
    @:to function toOriginal():T
        return this.obj;
}

现在我们在原始Point->Point方法的简化nearest版本中使用此摘要并对其进行测试。

// a test class for points with properties
// (points without properties can be tested with anonymous structs)
// don't use @:isVar, so that is clear that the getter was called
class TestPoint {
    var _x:Float;
    var _y:Float; 
    public var x(get,set):Float;
        function get_x() return _x;
        function set_x(x) return _x = x;
    public var y(get,set):Float;
        function get_y() return _y;
        function set_y(y) return _y = y;
    public function toString()
        return '(x:$x, y:$y)';
    public function new(x,y)
    {
        _x = x;
        _y = y;
    }
}

class Test {
    // a simplified function that takes some "point" and returns it back
    // it retains the basic type system problem as `nearest`
    public static function test<T>(p:SomePoint2<T>)
        return p;

    static function main()
    {
        // some points
        var p1 = { x:1., y:2. };
        var p2 = new TestPoint(1, 2);

        // calls to test
        var t1 = test(p1);
        var t2 = test(p2);
        $type(t1);
        $type(t2);

        // show that identity has been preserved
        // t1,t2 both get cast back to their original types
        trace(t1 == p1);
        trace(t2 == p2);

        // show explicit conversions
        trace((t1:{x:Float, y:Float}));
        trace((t2:TestPoint));
        // trace((t1:TestPoint));  // fails as expected: SomePoint2<{ y : Float, x : Float }> should be TestPoint 
    }
}

注意：我觉得这个解决方案可以很容易地改进（两个@:from实现都是相同的），但它是凌晨3点，没有别的想法。如果我最终弄清楚如何简化这一点，我会回来编辑它。

Answer 2

这是不可能的，因为Haxe getter / setter在编译时被解析了。

这意味着编译器使用适当的getter调用（p.x）替换属性lookup（p.get_x()），这意味着类型必须包含x和{{ 1}}是y。

要告诉编译器您的(get,set)类型需要有T和x，您可以创建类似的类型：

然后使用typedef PointProps = { var x(get,set): Float; var y(get,set): Float; }

显然你的方法不再适用于简单的变量了。

即使使用<T:PointProps>，似乎也无法使用与变量和属性兼容的单一方法。

是否可以在类字段和属性中使用Haxe类型约束？

2 个答案: