Question

我使用以下函数将DataGrid放在一起

 public function get dataGridColumns():Array {
    var dataGridColumnArray:Array = [];
    dataGridColumnArray.push(createDataGridColumn(col1, "field1", 0.17, sortStrings));
    dataGridColumnArray.push(createDataGridColumn(col2, "field2", 0.17, sortStrings));
    dataGridColumnArray.push(createDataGridColumn(col3, "field3", 0.17, sortStrings));
    return dataGridColumnArray;
}

private static function createDataGridColumn(columnName:String, dataField:String, width:Number,sortCompareFunction:Function = null):DataGridColumn {
    var column:DataGridColumn = new DataGridColumn(columnName);
    column.dataField = dataField;
    column.width = width;
    column.sortCompareFunction = sortCompareFunction;
    return column
}

private function sortStrings(a:Object, b:Object, fields:Array = null):int{
    if(a.toString().toLowerCase() > b.toString().toLowerCase()){
        return 1;
    }else if(a.toString().toLowerCase() < b.toString().toLowerCase()){
        return -1;
    }else{
        return 0;
    }
}

由于我的dataProvider是一个数据对象数组，我遇到的问题是sort函数中的a和b是对象，我想以某种方式将数据字段（列标题）传递给排序，以便我可以检查正确对象属性全部使用一个排序函数，所以它看起来像：

private function sortStrings(a:Object, b:Object, field:String):int{
    if(a.field.toLowerCase() > b.field.toString().toLowerCase()){
        return 1;
    }else if(a.field.toString().toLowerCase() < b.field.toString().toLowerCase()){
        return -1;
    }else{
        return 0;
    }
}

我还没有找到一个很好的方法来做到这一点，最坏的情况我有6个非常相似的排序函数。

Answer 1

你可以创建一个比较器工厂函数，它将返回闭包，包含字段名称：

private function createComparatorFor(field:String):Function {
    return function (a:Object, b:Object, fields:Array = null):int{
        const aField:String = a[field].toString().toLowerCase();
        const bField:String = b[field].toString().toLowerCase();

        if (aField > bField) {
            return 1;
        }

        if (aField < bField) {
            return -1;
        }

        return 0;
    }
}

并像这样使用它：

dataGridColumnArray.push(createDataGridColumn(
    col1, "field1", 0.17, createComparatorFor("field1")));

未经测试，但应该正常工作

在AS3中的DataGridColumns中重用sortCompareFunction

1 个答案: