Question

我想在N位容器中编码数字并以UDP数据包发送它们。接收器将知道N，并且接收器将从正好N位获取数字。（N <= 64）

有些想法：

sub to56BIT {
     return pack("??", shift);
}

sub to24BIT {
     return pack("??", shift);
}

my $n = 7;
to24BIT($n);

在接收方：

int n = Get_val24(byte_stream, offset);

在Perl中有没有办法做到这一点？

我认为解决方案可能是：

sub packIntN {
        my $int = shift;
        my $length = shift;
        return pack("B" . $length, substr(unpack("B64", pack("Q>", $int)), 64 - $length));
}

但也许有更优雅的方式。

输入/输出示例：我们有一个脚本test.pl：

use strict;
use warnings;

sub to24BIT {
        #???
}

my $n = 7;

print to24BIT($n);

我想要这个：

./test.pl | hexdump -C
00000000  00 00 07                                          |...|
00000003

另一个脚本test2.pl：

use strict;
use warnings;

sub to40BIT {
        #???
}

my $n = 7;

print to40BIT($n);

我想要这个：

./test.pl | hexdump -C
00000000  00 00 00 00 07                                    |.....|
00000005

Answer 1

N总是8的整数因子（8,16,24,32,40,48,56,64之一）？如果是这样，为了提高速度，我建议为每种尺寸编写一个封隔器，并使用调度表找到合适的封隔器。

sub pack_8bit  {        pack('C',  $_[0])     }
sub pack_16bit {        pack('S>', $_[0])     }
sub pack_24bit { substr(pack('L>', $_[0]), 1) }
sub pack_32bit {        pack('L>', $_[0])     }
sub pack_40bit { substr(pack('Q>', $_[0]), 3) }
sub pack_48bit { substr(pack('Q>', $_[0]), 2) }
sub pack_56bit { substr(pack('Q>', $_[0]), 1) }
sub pack_64bit {        pack('Q>', $_[0])     }

{
   my %packers = (
       8 => \&pack_8bit,   40 => \&pack_40bit,
      16 => \&pack_16bit,  48 => \&pack_48bit,
      24 => \&pack_24bit,  56 => \&pack_56bit,
      32 => \&pack_32bit,  64 => \&pack_64bit,
   );

   sub pack_num {
      my $packer = $packers{$_[0]}
         or die;
      return $packer->($_[1]);
   }

   sub get_packer {
      my $packer = $packers{$_[0]}
         or die;
      return $packer;
   }
}

my $packed = pack_num(40, 7);
  -or-
my $packer = get_packer(40);
my $packed = $packer->(7);

如果您计划将多个数字打包成一个字符串（例如pack('L>*', @nums)），我也会使用这样的调度表，但我不确定会是什么最快的pack_24bit，pack_40bit，pack_48bit和pack_56bit实施（除了C解决方案）。

Answer 2

请记住，你将永远拥有一个整体字节数，我最后用

substr(pack("Q>",$n<<(64-$len)),0,($len+7)/8);

和

unpack("Q>",$s.(0 x 8)) >> (64-$len);

在本例中尝试过：

#!/usr/bin/perl
$len = 40;
$n = 7;
$s = substr(pack("Q>",$n<<(64-$len)),0,($len+7)/8);
open(PIPE,"| hexdump -C");
print PIPE $s;
close PIPE;

$v = unpack("Q>",$s.(0 x 8)) >> (64-$len);
printf "%d\n",$v;

Perl：将int打包为任意长度的字节字符串

2 个答案: