Question

我有以下配置文件，我试图解析。

[ main ]
e_type=0x1B
username="username"
appname="applicationname"

在下面指定的lex文件（test.l）中，STR的正则表达式为\"[^\"]*\"，因此它可以识别引号内的所有内容。当我在解析器中访问"username" or "applicationname"的值时使用$ N变量的文件，它包含文字字符串。我只想要 username和applicationname，即没有字符串引号。

是否有一种标准方法可以实现这一目标。

我有以下lex文件（test.l）

%option noyywrap
%option yylineno
%{
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include "y.tab.h"

int yylinenu = 1;
int yycolno=1;

/**
 * Forward declerations
 **/
void Number ();
void HexaNumber ();
unsigned char getHexaLex (char c);
unsigned int strtol16 (char * str);


%}

%option nounput
%option noinput
%option case-insensitive

/*-----------------------------------------------------------------
   Some macros (standard regular expressions)
------------------------------------------------------------------*/

DIGIT       [0-9]
HEXALETTER  [a-fA-F]
HEXANUMBER  [0][x](({DIGIT}|{HEXALETTER})+)
NUM         {DIGIT}+
HEXA        ({DIGIT}|{HEXALETTER}|[*])
STR         \"[^\"]*\"
WSPACE      [ \t]*
NEWLINE     [\n\r]        

/*----------------------------------------------------------------
   The lexer rules
------------------------------------------------------------------*/
%%

e_type                   { yylval.str = yytext; return T_E_TYPE; }
main                     { yylval.str = yytext; return T_MAIN_SECTION;}
{HEXANUMBER}             { yylval.n = atoi(yytext);  HexaNumber(); return T_NUMBER; }
=                        { return T_EQUAL; }
"["                      { return T_OPEN_BRACKET; }
"]"                      { return T_CLOSE_BRACKET;}
appname                  { Custom_tag(); return T_APPNAME; }
username                 { Custom_tag(); return T_APPNAME; }

[^\t\n\r]                { }
{WSPACE}                 { } /* whitespace: (do nothing) */
{NEWLINE}                {  
                            yylinenu++;
                            return T_EOL;
                         }
{STR}                    { Generic_string(); return T_STRING;}                      

%%

void Number () {
    yylval.n = atol(yytext);
}

void Generic_string() {
    yylval.str = malloc(strlen(yytext)+1);
    strcpy (yylval.str, yytext);
}

Answer 1

您有指向匹配令牌（yytext）及其长度（yyleng）的指针，因此删除引号非常简单：

void Generic_string() {
    yylval.str = malloc(yyleng - 1);  // length - 2 (quotes) + 1 (NUL)
    memcpy (yylval.str, yytext + 1, yyleng - 2); // copy all but quotes
    yylval.str[yyleng - 2] = 0;                  // NUL-terminate
}

就个人而言，我建议避免在Generic_string中使用全局变量，以简化可重入扫描程序的未来实现，并使该过程更灵活：

{STR}   { yylval.str = duplicate_segment(yytext + 1, yyleng - 2);
          return T_STRING;
        }

  /* ... */

char* duplicate_segment(const char* token, int token_length) {
  char* dup = malloc(token_length + 1);
  if (!dup) { /* handle memory allocation error */ }
  memcpy(dup, token, token_length);
  dup[token_length] = 0;
  return dup;
}

字符串的正则表达式，不包括文字引号

1 个答案: