Question

在将矩阵A和向量x相乘得到结果y之后，我想将元素h元素应用于y。

我想获得z = h（A x），其中h元素应用于向量A x。

我知道如何在GPU（使用cublas）上进行矩阵/向量乘法。现在我希望h（这是我自己的函数，用C ++编写）也应用于GPU中的结果向量，我该怎么做？

Answer 1

两种可能的方法是：

编写自己的CUDA内核以执行操作
使用thrust（例如thrust::for_each()）。

以下是两种方法的实例：

$ cat t934.cu
#include <iostream>
#include <thrust/host_vector.h>
#include <thrust/device_vector.h>
#include <thrust/copy.h>
#include <thrust/for_each.h>

#define DSIZE 4

#define nTPB 256

template <typename T>
__host__ __device__ T myfunc(T &d){

  return d + 5;  // define your own function here
}

struct mytfunc
{
template <typename T>
__host__ __device__
 void operator()(T &d){

  d = myfunc(d);
  }
};

template <typename T>
__global__ void mykernel(T *dvec, size_t dsize){

  int idx = threadIdx.x+blockDim.x*blockIdx.x;
  if (idx < dsize) dvec[idx] = myfunc(dvec[idx]);
}

int main(){

  // first using kernel
  float *h_data, *d_data;
  h_data = new float[DSIZE];
  cudaMalloc(&d_data, DSIZE*sizeof(float));
  for (int i = 0; i < DSIZE; i++) h_data[i] = i;
  cudaMemcpy(d_data, h_data, DSIZE*sizeof(float), cudaMemcpyHostToDevice);
  mykernel<<<(DSIZE+nTPB-1)/nTPB,nTPB>>>(d_data, DSIZE);
  cudaMemcpy(h_data, d_data, DSIZE*sizeof(float), cudaMemcpyDeviceToHost);
  for (int i = 0; i < DSIZE; i++) std::cout << h_data[i] << ",";
  std::cout << std::endl;

  // then using thrust
  thrust::host_vector<float>   hvec(h_data, h_data+DSIZE);
  thrust::device_vector<float> dvec = hvec;
  thrust::for_each(dvec.begin(), dvec.end(), mytfunc());
  thrust::copy_n(dvec.begin(), DSIZE, std::ostream_iterator<float>(std::cout, ","));
  std::cout << std::endl;
}

$ nvcc -o t934 t934.cu
$ ./t934
5,6,7,8,
10,11,12,13,
$

请注意，为了提供完整的示例，我从主机内存中的向量定义开始。如果你已经在设备内存中有了向量（可能是计算y = Ax的结果），那么你可以直接使用它，通过将该向量传递给CUDA内核，或者直接在推力函数中使用它，使用{{ 1}}包装器（此方法在先前链接的推力快速入门指南中介绍。）

我在这里做的假设是你想要使用一个变量的任意函数。这应该处理thrust::device_ptr中定义的几乎任意函数。但是，对于您可能感兴趣的某些类别的函数，您也可以实现一个或多个CUBLAS调用。

cuda中的cuda函数应用元素

1 个答案: