Question

我是vhdl的新手，我已经编写了12位二进制计数器的代码，并且我收到了这个错误（意外的TOKBEGIN，期待AFFECT或SEMICOLON）。请指导我解决此错误

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
-- Uncomment the following library declaration if using
-- arithmetic functions with Signed or Unsigned values
use IEEE.NUMERIC_STD.ALL;

-- Uncomment the following library declaration if instantiating
-- any Xilinx primitives in this code.
--library UNISIM;
--use UNISIM.VComponents.all;

entity bin_count is
Port ( clk : in  STD_LOGIC;
       reset : in  STD_LOGIC;
       seq : out  STD_LOGIC_VECTOR (11 downto 0));
end bin_count;

architecture Behavioral of bin_count is
signal  ff, ff_next, max_pulse : std_logic_vector(11 downto 0)
begin
process(clk,reset)
begin
if(reset = '1') then
ff <= "000000000000"
elsif( rising_edge(clk)) then
ff <= ff_next
end if
end process;
ff_next <= ff + 1;
max_pulse <= '1' when ff = "111111111111" else
0;
seq<= ff
end

end Behavioral;

错误是;

ERROR:HDLParsers:164 - "C:/.Xilinx/New folder/bin_count/bin_count.vhd" Line 39. parse error, unexpected TOKBEGIN, expecting AFFECT or SEMICOLON

Answer 1

您的个人资料显示您未点击Tour（位于“帮助”下）。巡回赛建议在提问之前搜索网站。在这种情况下搜索没有找到一个回答错误的问题：HDLParsers：164还提到了预期的分号。

在VHDL中，分号是语句和声明的分隔符。使用是如此基本，以至于您无法找到LRM中其他任何地方展示的要求，但扩展BNF解决了如何解析VHDL语法。

你错过了很多分号，这可能意味着在介绍VHDL的地方没有提到使用分隔符。

示例代码中的错误
除了5个缺少分号外，没有可见的“+”运算符（ff不是无符号或有符号值 - 使用包numeric_std_unsigned而不是numeric_std或使用类型转换）。

对max_plus选项的赋值不是std_logic_vector的子类型max_plus（“111111111111”和“0000000000000”而不是'1'和0）的值的表达式。

有一个错误的（额外的）结束语句（也没有分号）。

第一个错误显示在您示例的第26行，没有第39行。您可以指出该位置。

architecture behavioral of bin_count is
    signal  ff, ff_next, max_pulse: 
            std_logic_vector(11 downto 0); -- missing semicolon
begin
    process(clk, reset)
    begin
        if reset = '1' then
            ff <= "000000000000";          -- missing semicolon
        elsif  rising_edge(clk) then
            ff <= ff_next;                 -- missing semicolon
        end if;                            -- missing semicolon
    end process;

   --  ff_next <= ff + 1;     -- no visible operator "+"
   ff_next <= std_logic_vector(unsigned(ff) + 1); -- type converts ff to unsigned
                                                  -- and the result back
    -- or in the context clause use numeric_std_unsigned:
-- use ieee.numeric_std_unsigned.all;  -- makes "+" visible
    -- instead of numeric_std;
    -- 
    -- and here:
    -- ff_next <= ff + 1;

    -- abstract literal 0  and enumeration literal '1' are not values
    -- of std_logic_vector:

    -- max_pulse <= '1' when ff = "111111111111" else
    --              '0'; 

    -- use string literal instead:
    max_pulse <= "111111111111" when ff = "111111111111" else
                 "000000000000";

    -- (and there are other expressions available)

    seq <= ff;                              -- missing semicolon
-- end         -- errant end statement - this doesn't match anything.

end behavioral;

通过上述更改，您的代码将进行分析。还可以进行一些其他更改。

max_pulse不需要是std_logic_vector，它可以是std_logic。（这将允许使用'1'和'0'作为条件赋值语句中指定的值。

不需要ff_next。

这些给我们一个稍微不同的架构：

architecture foo of bin_count is
    signal  ff:         std_logic_vector(11 downto 0);
    signal max_pulse:   std_logic;
begin
    process(clk, reset)
    begin
        if reset = '1' then
            ff <= (others => '0');         -- an aggregate
        elsif  rising_edge(clk) then
            ff <= std_logic_vector(unsigned(ff) + 1); 
        end if;                  
    end process;   

    max_pulse <= '1' when ff = "111111111111" else
                 '0';                 
    seq <= ff;

end architecture;

使用测试平台：

library ieee;
use ieee.std_logic_1164.all;

entity bin_count_tb is
end entity;

architecture fum of bin_count_tb is
    signal clk:     std_logic := '0'; -- default value
    signal reset:   std_logic;
    signal seq:     std_logic_vector (11 downto 0);
begin
CLOCK:
    process
    begin
        wait for 5 ns; -- half the clock period
        clk <= not clk; 
        if now > 85000 ns then -- now returns simulation time
            wait;
        end if;
    end process;
DUT:    
    entity work.bin_count
        port map (
            clk => clk,
            reset => reset,
            seq => seq
        );
STIMULUS:
    process
    begin
        reset <= '1';
        wait for 11 ns;
        reset <= '0';
        wait;
    end process;

end architecture;

我们可以看到重置：

（点击）

我们可以看到max_pulse定期发生：

（点击）

我们可以在max_pulse occurs：

时看到seq = "111111111111"

（点击）

意外的TOKBEGIN，期待AFFECT或SEMICOLON

1 个答案: