Question

我已经看到了我的问题的变种 how-to-merge-two-xml-files-with-xslt 要么 how-can-i-merge-these-two-xml-files-using-xslt，但这些示例不处理文本输出，也不处理静态引用＆＃39; default.xml＆＃39;。

我正在尝试生成一个由defaults.xml生成的C头文件，该头文件由target.xml修改。

我正在使用xsltproc作为xslt处理器，并希望能够做到 xslproc merg.xsl target1.xml > target1.h。

有一个defaults.xml文件和不同的target.xml文件的意思

示例defaults.xml：

＆＃13;

<?xml version="1.0" encoding="UTF-8"?>

<defaults>
<ConfigParam name="F_SAMPLE_STRING">
  <value>{1,0,0}</value>
</ConfigParam>

<ConfigParam name="F_SAMPLE_INT">
  <value>40</value>
</ConfigParam>

<ConfigParam name="F_SAMPLE_X">
  <value>TRUE_DEF</value>
</ConfigParam>

</defaults>

＆＃13;

＆＃13; 和一个示例target1.xml

＆＃13;

<?xml version="1.0" encoding="UTF-8"?>
<Override>
		<ConfigParam name="F_SAMPLE_STRING">
		  <value>"hallo"</value>
		</ConfigParam>

		<ConfigParam name="F_SAMPLE_Y">
		  <value>TRUE</value>
		</ConfigParam>
</Override>

＆＃13;

我自己的首发xslt看起来像这样，但缺少合并/修改部分

＆＃13;

<?xml version="1.0"?>

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/> 
<xsl:param name="fileName" select=" 'defaults.xml' " />
<xsl:param name="defaults" select="document($fileName)" />
<xsl:variable name="defaultParams" select="$defaults//ConfigParam" />


  <xsl:template match="@* | node() ">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  
  <xsl:template match="ConfigParam">
  #define <xsl:value-of select="@name"/><xsl:text> </xsl:text><xsl:value-of select="value"/>    <xsl:text>&#xd;&#xa;</xsl:text> 
  </xsl:template>

</xsl:stylesheet>

＆＃13;

我看到的其他示例使用静态target.xml或使用静态位置的两个文件（目标/默认值）。它们也不输出文本而是xml。我是xslt的新手，无法想出一个良好的合并身份模式。请帮忙。

Answer 1

如果我理解正确，你想做：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/> 
<xsl:strip-space elements="*"/>

<xsl:param name="path-to-defaults" select="'defaults.xml'" />
<xsl:variable name="defaults" select="document($path-to-defaults)/defaults/ConfigParam" />
<xsl:variable name="overrides" select="/Override/ConfigParam" />

<xsl:template match="/">
    <xsl:apply-templates select="$defaults[not(@name = $overrides/@name)]" />
    <xsl:apply-templates select="$overrides" />
</xsl:template>     

<xsl:template match="ConfigParam">
    <xsl:text>#define </xsl:text>
    <xsl:value-of select="@name"/>
    <xsl:text> </xsl:text>
    <xsl:value-of select="value"/>
    <xsl:text>&#xd;&#xa;</xsl:text> 
</xsl:template>  

</xsl:stylesheet>

这假设您将处理target1.xml文件并指向常量defaults.xml文件。结果如下：

#define F_SAMPLE_INT 40
#define F_SAMPLE_X TRUE_DEF
#define F_SAMPLE_STRING "hallo"
#define F_SAMPLE_Y TRUE

注意：使用文本输出时，您不希望使用标识转换模板。

如何使用xslt生成文本输出合并两个xml文件

1 个答案: