Question

我想证明终止意味着存在正常形式。这些是我的定义：

Section Forms.
  Require Import Classical_Prop.
  Require Import Classical_Pred_Type.
  Context {A : Type}
  Variable R : A -> A -> Prop.

  Definition Inverse (Rel : A -> A -> Prop) := fun x y => Rel y x.  

  Inductive ReflexiveTransitiveClosure : Relation A A :=
  | rtc_into (x y : A) : R x y -> ReflexiveTransitiveClosure x y
  | rtc_trans (x y z : A) : R x y -> ReflexiveTransitiveClosure y z ->
                            ReflexiveTransitiveClosure x z
  | rtc_refl (x y : A) : x = y -> ReflexiveTransitiveClosure x y.

  Definition redc (x : A) := exists y, R x y.
  Definition nf (x : A) := ~(redc x).
  Definition nfo (x y : A) := ReflexiveTransitiveClosure R x y /\ nf y.
  Definition terminating := forall x, Acc (Inverse R) x.
  Definition normalizing := forall x, (exists y, nfo x y).
End Forms.

我想证明：

Lemma terminating_impl_normalizing (T : terminating):
  normalizing.

我现在已经把头撞到墙上几个小时了，而且我几乎没有任何进展。我可以证明：

Lemma terminating_not_inf_forall (T : terminating) :
  forall f : nat -> A, ~ (forall n, R (f n) (f (S n))).

我认为应该有所帮助（没有经典也是如此）。

Answer 1

这是使用排除中间的证据。我重新阐述了用标准定义替换自定义定义的问题（注意，在你的闭包定义中，rtc_into与其他定义是多余的）。我还使用terminating重新构造了well_founded。

Require Import Classical_Prop.
Require Import Relations.

Section Forms.
  Context {A : Type} (R:relation A).

  Definition inverse := fun x y => R y x.

  Definition redc (x : A) := exists y, R x y.
  Definition nf (x : A) := ~(redc x).
  Definition nfo (x y : A) := clos_refl_trans _ R x y /\ nf y.
  Definition terminating := well_founded inverse. (* forall x, Acc inverse x. *)
  Definition normalizing := forall x, (exists y, nfo x y).

  Lemma terminating_impl_normalizing (T : terminating):
    normalizing.
  Proof.
    unfold normalizing.
    apply (well_founded_ind T). intros.
    destruct (classic (redc x)).
    - destruct H0 as [y H0]. pose proof (H _ H0).
      destruct H1 as [y' H1]. exists y'. unfold nfo.
      destruct H1.
      split.
      + apply rt_trans with (y:=y). apply rt_step. assumption. assumption.
      + assumption.
    - exists x. unfold nfo. split. apply rt_refl. assumption.
Qed.

End Forms.

证明不是很复杂，但这里有主要的想法：

使用有根据的归纳
由于排除中间原则，将x不正常的情况与
如果x不是正常形式，请使用归纳假设并使用闭包的传递性来结束
如果x已经处于正常状态，我们就完成了

终止意味着存在正常形式

1 个答案: