Question

我在WX界面中使用Reactive-Banana。我需要在按下按钮时从外部服务API检索值。

我有一个基于数据类型Behavior的通用AppState，它根据函数转换（doSomeTransformation）“累积”转换后的更改。转换的值由事件传输，当按下界面上的按钮时，它们来自远程API（getRemoteValue）。我编写了代码的精简版，代表了必不可少的部分：

module Main where

{-# LANGUAGE ScopedTypeVariables #-} -- allows "forall t. Moment t"

import Graphics.UI.WX hiding (Event)
import Reactive.Banana
import Reactive.Banana.WX

{-----------------------------------------------------------------------------
    Main
------------------------------------------------------------------------------}
data AppState = AppState {
    count :: Int
} deriving (Show)

type String = [Char]

main :: IO ()
main = start $ do
    f        <- frame [text := "AppState"]
    myButton <- button f [text := "Go"]
    output   <- staticText f []

    set f [layout := margin 10 $
            column 5 [widget myButton, widget output]]

    let networkDescription :: forall t. Frameworks t => Moment t ()
        networkDescription = do

        ebt   <- event0 myButton command

        remoteValueB <- fromPoll getRemoteApiValue
        myRemoteValue <- changes remoteValueB

        let            
            doSomeTransformation :: AppState -> AppState
            doSomeTransformation ast = ast { count = count ast }

            coreOfTheApp :: Behavior t AppState
            coreOfTheApp = accumB initialState $ (doSomeTransformation to combine with myRemoteValue) <$ ebt

        sink output [text :== show <$> coreOfTheApp]

    network <- compile networkDescription    
    actuate network

getRemoteApiValue :: IO Int
getRemoteApiValue = return 5

和cabal conf：

name:                brg
version:             0.1.0.0
synopsis:            sample frp gui
-- description:
license:             PublicDomain
license-file:        LICENSE
author:              me
maintainer:          me@gmail.com
-- copyright:
category:            fun
build-type:          Simple
-- extra-source-files:
cabal-version:       >=1.10

executable bgr
  main-is:             Main.hs
  -- other-modules:
  -- other-extensions:
  build-depends:       base >=4.7 && <4.8
                       , text
                       , wx ==0.92.0.0
                       , wxcore ==0.92.0.0
                       , transformers-base
                       , reactive-banana >=0.9 && <0.10
                       , reactive-banana-wx ==0.9.0.2
  hs-source-dirs:      src
  default-language:    Haskell2010
  ghc-options:         -Wall -O2

我的问题是如何以一种我可以将远程API值用作正常事件值的方式撰写doSomeTransformation和myRemoteValue。来自banana-reactive的changes具有以下特征：

changes :: Frameworks t => Behavior t a -> Moment t (Event t (Future a))

它会将IO Int包裹起来getRemoteApiValue。

所以基本上我该怎么做：

IO Int -> Moment t (Event t (Future AppState)) -> AppState

BTW我不确定这个不同的功能签名是否更清晰： doSomeTransformation :: Int -> AppState -> AppState，其中Int值由API返回值表示。听起来像是两个Behavior和一个流。也许是一个解决问题的坏方法？

Answer 1

简答：转换函数需要再接受一个参数，来自API的值：

transformState v (AppState x) = AppState $ x + v

并且您需要使用<$>（即应用函数）而不是<$（即使用常量值覆盖）：

accumB (AppState 0) $ transformState <$> remoteValueB <@ ebt

答案很长：

注意：我已重命名/更改了一些内容，因此请相应地阅读我的解释

需要更改的是使用accumB折叠传入值的方式。 accumB的工作方式是将一系列函数a -> a应用于种子值a，以计算类型a的最终值。您当前折叠API值的方法是始终将应用程序状态计数增量函数应用于初始状态，完全丢弃传入的值（使用<$）。相反，您需要使用<$> 映射传入的值，而不是替换它。你需要将值映射到什么？一个函数（根据accumB的类型）！该功能是transformValue eventValue :: AppState -> AppState。

基于列表和折叠的示例：

*Frp> data State = State Int deriving Show
*Frp> let transform x (State c) = State $ x + c
*Frp> let xs = [1, 2, 3, 4, 5]                       -- the API values
*Frp> let xsE = transform <$> xs :: [State -> State] -- the event stream
*Frp> let accumB = foldr ($)
*Frp> accumB (State 0) xsE
State 15

（不要忘记a <$> b与fmap a b相同，或者在列表的情况下只是map a b

现在考虑一下你现在的覆盖方式＆＃34;来自remoteValueB <@ ebt的任何事件（函数）常量transformState，这意味着所有到达的覆盖事件始终保持相同的内容：transformState函数。

相反，你想要的是将传入的值映射到一些实际函数，例如一个采用旧状态并将其与到达值组合并产生新状态值的函数：

remoteValueE :: Event t Int
remoteValueE = remoteValueB <@ ebt

transformsE :: Event t (AppState -> AppState)
transformsE = transformState <$> remoteValueE

coreOfTheApp :: Behavior t AppState
coreOfTheApp = accumB initialState $ transformsE

我还更改了getRemoteApiValue以返回更改值来模仿真实的API。因此，通过对代码进行一些修改，可以使用以下内容：

import System.Random

type RemoteValue = Int

-- generate a random value within [0, 10)
getRemoteApiValue :: IO RemoteValue
getRemoteApiValue = (`mod` 10) <$> randomIO

data AppState = AppState { count :: Int } deriving Show

transformState :: RemoteValue -> AppState -> AppState
transformState v (AppState x) = AppState $ x + v

main :: IO ()
main = start $ do
    f        <- frame [text := "AppState"]
    myButton <- button f [text := "Go"]
    output   <- staticText f []

    set f [layout := minsize (sz 300 200)
                   $ margin 10
                   $ column 5 [widget myButton, widget output]]

    let networkDescription :: forall t. Frameworks t => Moment t ()
        networkDescription = do    
          ebt <- event0 myButton command

          remoteValueB <- fromPoll getRemoteApiValue
          myRemoteValue <- changes remoteValueB

          let
            events = transformState <$> remoteValueB <@ ebt

            coreOfTheApp :: Behavior t AppState
            coreOfTheApp = accumB (AppState 0) events

          sink output [text :== show <$> coreOfTheApp] 

    network <- compile networkDescription    
    actuate network

Reactive Banana：如何使用远程API中的值并将它们合并到事件流中

1 个答案: