Question

假设我有以下XML：

 <DataDictionary numberOfFields="5">
  <DataField name="Species" optype="categorical" dataType="string">
   <Value value="setosa"/>
   <Value value="versicolor"/>
   <Value value="virginica"/>
  </DataField>
  <DataField name="Sepal.Length" optype="continuous" dataType="double"/>
  <DataField name="Sepal.Width" optype="continuous" dataType="double"/>
  <DataField name="Petal.Length" optype="continuous" dataType="double"/>
  <DataField name="Petal.Width" optype="continuous" dataType="double"/>
 </DataDictionary>

有人可以提供一个正则表达式（例如vim或sed）来使所有属性名称都大写吗？

例如，我希望numberOfFields为NumberOfFields而dataType为DataType。

Answer 1

使用sed处理XML通常不是一个好主意，因为sed以基于行的方式工作，而XML并不真正关心换行符。例如，你可以有

<foo bar=
   "baz"/>

完全有效的XML，使用sed（或其他纯文本工具）很难处理。

我建议使用XSLT样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>
  <xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*">
    <xsl:variable name="capname"
                  select="concat(translate(substring(name(.),1,1), $vLower, $vUpper), substring(name(.), 2))"/>
    <xsl:attribute name="{$capname}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

将它放在一个文件中，比如说foo.xsl，然后使用像xsltproc这样的XSLT处理器来运行它：

xsltproc foo.xsl foo.xml

其中foo.xml是您的XML文件。或者，使用xalan：

xalan -xsl foo.xsl -in foo.xml

任何XSLT处理器都可以;对于其他人，请查看他们的联系方式。

其工作原理如下：

  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

是适用于所有节点的identity transform（在这种情况下不是属性，因为它们在别处处理）并递归地应用模板。这使得转换的输出是输入的副本，其中没有其他模板适用。肉在

  <xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>
  <xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

  <xsl:template match="@*">
    <xsl:variable name="capname"
                  select="concat(translate(substring(name(.),1,1), $vLower, $vUpper), substring(name(.), 2))"/>
    <xsl:attribute name="{$capname}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>

这适用于所有属性（@*）。

concat(translate(substring(name(.),1,1), $vLower, $vUpper), substring(name(.), 2))

是属性名称的大写版本，并将其分配给变量capname。然后

<xsl:attribute name="{$capname}">
  <xsl:value-of select="."/>
</xsl:attribute>

使用该大写名称和旧值代替旧的非大写属性插入新属性。

这适用于所有有效的XML输入。

Answer 2

使用正确的XML处理工具，sed无法轻松处理所有可能的XML语法规则。

使用xsh，一个XML编辑shell，例如：

open file.xml ;
rename { ucfirst } //@* ;
# OR, to avoid any Perl:
# rename xsh:ucfirst(name()) //@* ;
save :b ;

大写所有XML属性名称

2 个答案: