Question

我在Delphi XE2中使用TIdHTTPServer充当基本的HTML服务器，以从Web获取请求，处理它们并回馈所需的响应。

问题是当有人打开localhost:5678/book?name=Петров这样的页面时，我无法正确接收“Петров”这个名称。

此过程很简单：

procedure TMain.IdHTTPServer1CommandGet(AContext: TIdContext;
  ARequestInfo: TIdHTTPRequestInfo; AResponseInfo: TIdHTTPResponseInfo);
var
  Aux_S1          : String;
  Aux_S2          : String;
begin

  Aux_S1 := ARequestInfo.Params[0];

  Aux_S2 := System.UTF8Decode(ARequestInfo.Params[0]);

end;

Aux_S1是'name=Ð'#$009F'ÐµÑ'#$0082'Ñ'#$0080'Ð¾Ð²'

Aux_S2是'name=�?е�?�?ов'

有些字母正确显示但有些字母则没有。

我做错了什么，或者我该如何处理这些请求？

Answer 1

不允许URL包含非ASCII字符。这些字符必须是charset编码为字节，然后在放入URL时以%HH格式编码。那么，您的客户端实际使用的URL是更像这样的东西：

http://localhost:5678/book?name=%D0%9F%D0%B5%D1%82%D1%80%D0%BE%D0%B2

%D0%9F%D0%B5%D1%82%D1%80%D0%BE%D0%B2为Петров，采用UTF-8百分比编码格式。

URL无法指定用于此类编码的字符集。由服务器决定。但UTF-8是最常用的字符集编码。

如果TIdHTTPServer属性为true（默认为默认值），

OnCommandGet会在触发ParseParams事件之前自动解析和解码URL查询字符串。所以不要直接在参数字符串上调用UTF8Decode()，因为它不起作用。

不幸的是，TIdHTTPServer目前不允许您指定用于解码查询字符串的哪个字符集（即在TODO列表中）。它的作用是检查请求是否在charset标头中包含Content-Type属性，如果是，则使用它（不过这不是标准的HTTP服务器行为），否则它使用Indy的内置改为8位编码。

后一种情况是GET次请求中经常发生的情况，因为它们没有Content-Type标头。尽管如此，这对你有利（见下文）。字符串值：

'Ð'#$009F'ÐµÑ'#$0082'Ñ'#$0080'Ð¾Ð²'

实际上，Петров的原始UTF-8字节在解码为UnicodeString时被解释为8位“字符”：

#$00D0 #$009F #$00D0 #$00B5 #$00D1 #$0082 #$00D1 #$0080 #$00D0 #$00BE #$00D0 #$00B2

因此，您可以通过手动将解码后的参数字符串转换回原始字节来“修复”此解码不匹配，然后将它们解码为UTF-8，重新转换为字符串，例如：

procedure TMain.IdHTTPServer1CommandGet(AContext: TIdContext;
  ARequestInfo: TIdHTTPRequestInfo; AResponseInfo: TIdHTTPResponseInfo);
var
  Aux_S1: String;
begin
  // if you are not using Indy 10.6+, you can replace
  // IndyTextEncoding_UTF8 with TIdTextEncoding.UTF8,
  // and IndyTextEncoding_8bit with Indy8BitEncoding...
  //
  //Aux_S1 := TIdTextEncoding.UTF8.GetString(ToBytes(ARequestInfo.Params[0], Indy8BitEncoding));
  Aux_S1 := IndyTextEncoding_UTF8.GetString(ToBytes(ARequestInfo.Params[0], IndyTextEncoding_8bit));

end;

或者，将ParseParams设置为false并手动解码ARequestInfo.QueryParams字符串（来自URL的原始百分比编码数据）：

procedure DecodeParams(const AValue: String; Params: TStrings);
var
  i, j : Integer;
  s: string;

  // if you are not using Indy 10.6+, you can replace
  // IIdTextEncoding with TIdTextEncoding...
  //
  //LEncoding: TIdTextEncoding;
  LEncoding: IIdTextEncoding;
begin
  // Convert special characters
  // ampersand '&' separates values    {Do not Localize}
  Params.BeginUpdate;
  try
    Params.Clear;

    // if you are not using Indy 10.6+, you can replace
    // IndyTextEncoding_UTF8 with TIdTextEncoding.UTF8...
    //
    //LEncoding := TIdTextEncoding.UTF8;
    LEncoding := IndyTextEncoding_UTF8;

    i := 1;
    while i <= Length(AValue) do
    begin
      j := i;
      while (j <= Length(AValue)) and (AValue[j] <> '&') do {do not localize}
      begin
        Inc(j);
      end;
      s := Copy(AValue, i, j-i);
      // See RFC 1866 section 8.2.1. TP
      s := ReplaceAll(s, '+', ' ');  {do not localize}
      Params.Add(TIdURI.URLDecode(s, LEncoding));
      i := j + 1;
    end;
  finally
    Params.EndUpdate;
  end;
end;

procedure TMain.IdHTTPServer1CommandGet(AContext: TIdContext;
  ARequestInfo: TIdHTTPRequestInfo; AResponseInfo: TIdHTTPResponseInfo);
var
  Aux_S1: String;
begin
  DecodeParams(LRequestInfo.QueryParams, ARequestInfo.Params);
  Aux_S1 := ARequestInfo.Params[0];    
end;

如何在TIdHTTPServer中接收包含外来字符的查询字符串

1 个答案: