Question

我的数据目前采用以下形式：

 ID     Fill1          Fill2         Fill3         Fill4          Fill5     
 1      01JAN2014      28JAN2014     26FEB2014     .              .
 2      .              05FEB2012     03MAR2012     02APR2012      01MAY2012
 3      10MAR2015      08APR2015     07MAY2015     05JUN2015      03JUL2015
 4      .              .             20FEB2013     18MAR2013      .

我正在努力为每个ID创建治疗“剧集”。换句话说，对于每个ID，我想找到第一个和最后一个非空填充，然后计算两个日期之间的差异。例如，对于ID = 1，我需要找到01JAN2014和26FEB2014之间的时差。也就是说，

Fill1 - Fill3 = episodeduration

但是对于ID = 4，我需要找到，

Fill3 - Fill4 = episodeduration

其中episodeduration是创建的新变量。我有超过30k的唯一ID，具有不同的“第一”和“最后”填充日期。在此先感谢您的帮助。

Answer 1

data have;
input Id Fill1 date9. Fill2 date9. Fill3 date9. Fill4 date9. Fill5 date9.;
format Fill1 -  Fill5 date9.;
cards;
1 01JAN201428JAN201426FEB2014 
2          05FEB201203MAR201202APR201201MAY2012
3 10MAR201508APR201507MAY201505JUN201503JUL2015
4                   20FEB201318MAR2013 
;
run;

data want;
set have;
    array fill {5};
    format first last date9.;

    do i = 1 to dim(fill);
       first=coalesce(first, fill(i));
       last=coalesce(fill(i), last);
    end;

    episodeduration = last - first;

    drop i;
run;

使用array语句创建数组并循环遍历变量，使用coalesce()函数查找第一个/最后一个非缺失。

评论：此代码将从第一个变量到最后一个变量找到第一个/最后一个。如果您在日期方面需要第一个/最后一个，那么最小和最大函数都是好的：min(of fill1 -- fill5); - 无需循环。

Answer 2

vasja的SAS版本看起来相当不错，这就是如何在SQL端完成（这几乎是完全相同的程序）。

Select *, 
    DATEDIFF(day, 
         CONVERT(date,COALESCE(date1, date2, date3, date4, date5)),
         CONVERT(date, COALESCE(date5,date4,date3,date2,date1))
    )
from SomeTableNameAboutEpisodes;

基本上，您使用coalesce查找第一个非null值，并将其转换为日期。然后你取两个日期之间的差异。但是，仅当空单元格没有值（null）且没有空行时才有效。（你可以简单地设一个 ISNULL（DATEDIF（...），0）。

Answer 3

您可以使用降序“SAS变量列表”（FILL5-FILL1）来简化此操作。

data diff;
   set have;
   first = coalesce(of fill1-fill5);
   i     = whichn(first,of fill1-fill5);
   last  = coalesce(of fill5-fill1);
   j     = 6-whichn(last, of fill5-fill1);
   format first last date9.;
   run;

Obs    Id        Fill1        Fill2        Fill3        Fill4        Fill5        first    i         last    j

 1      1    01JAN2014    28JAN2014    26FEB2014            .            .    01JAN2014    1    26FEB2014    3
 2      2            .    05FEB2012    03MAR2012    02APR2012    01MAY2012    05FEB2012    2    01MAY2012    5
 3      3    10MAR2015    08APR2015    07MAY2015    05JUN2015    03JUL2015    10MAR2015    1    03JUL2015    5
 4      4            .            .    20FEB2013    18MAR2013            .    20FEB2013    3    18MAR2013    4

使用SAS或SQL查找行中的第一个和最后一个非空值？

3 个答案: