Question

我试图在Github中获取某个仓库的分支，同样执行：

curl -k -X GET https://api.github.com/repos/rackt/redux/forks

但是在詹金斯的DSL脚本中。

为什么呢？因为我想克隆所有人的分叉，并在job-dsl-plugin生成的单独作业上构建项目。

当然这只是我发现的回购的一个例子。我尝试使用带有私有存储库的SSH凭据来执行此操作。

你知道哪种方法最好吗？

Answer 1

wiki中有一个真实世界的例子，其中详细说明了如何创建jobs for branches

def project = 'Netflix/asgard'
def branchApi = new URL("https://api.github.com/repos/${project}/branches")
def branches = new groovy.json.JsonSlurper().parse(branchApi.newReader())
branches.each {
    def branchName = it.name
    def jobName = "${project}-${branchName}".replaceAll('/','-')
    job(jobName) {
        scm {
            git("https://github.com/${project}.git", branchName)
        }
    }
}

您需要做的是将job部分移到each闭包之外并使用前缀名称。

关于ssh和私人回购的评论。最好使用Credentials plugin之类的wiki来保持您的ssh密钥不在脚本中

第一个选项涉及管理的Credentials Plugin 凭证以安全的方式提供，并允许Job DSL脚本引用凭证由他们的标识符。它也是最安全的选择因为凭据不需要传递给Job DSL脚本。

// use the github-ci-key credentials for authentication with GitHub
job('example-1') {
    scm {
        git {
            remote {
                github('account/repo', 'ssh')
                credentials('github-ci-key')
            }
        }
    }
}

Answer 2

我终于通过this (see the Gist I published)解决了问题：

import groovy.json.JsonSlurper

def owner = "<owner>"
def project = "<project>"

// curl -k -u <user>:<token> -X GET https://api.github.com/repos/<owner>/<repo>/forks > forks.txt

def fetch(addr, params = [:]) {
  def auth = "<personalAPIToken>" // see https://github.com/blog/1509-personal-api-tokens
  def json = new JsonSlurper()
  return json.parse(addr.toURL().newReader(requestProperties: ["Authorization": "token ${auth}".toString(), "Accept": "application/json"]))
}

def forks = fetch("https://api.github.com/repos/${owner}/${project}/forks")

forks.each {
    def fork = it.full_name
    def name = it.owner.login
    def jobName = "${project}-${name}".replaceAll('/','-')
    job(jobName) {
        scm {
            git {
              remote {
                github(fork, 'https')
                credentials('<idCredentials>')
              }
            }
        }
    }
}

谢谢！

Jenkins和Github的DSL工作

2 个答案: