Question

我正在开展一个学校项目，我想创建一个批处理文件，用于ping用户定义的IP范围，并将成功的ping写入txt文件。

现在我陷入FOR循环：

@echo off
SET /p IPRange=Bitte IP-Range eingeben(xxx.xxx.xxx) :
SET /p AnfangsIP=Bitte AnfangsIP des Bereiches eingeben :
SET /p EndIP=Bitte EndIP des Bereiches eingeben :

FOR /L %IP% (%AnfangsIP%,1,%EndIP%) DO (
    ping -n 1 %IP-Range%.%IP% | find "TTL=" >nul
    if errorlevel 1 (
        echo %IP-Range%.%IP% not reachable
    ) else (
        echo %IP-Range%.%IP% reachable
    )
)

pause>nul

使用以下参数执行批处理文件：IP范围，启动IP地址，结束IP地址。我的目标是创建一个for循环，在每个循环中递增变量%IP%。从start IP-address到end IP-address。

我在论坛中进行了搜索，但只有单一的ping不适用于所有IP。

Answer 1

试试这个：

@echo off

SET /p IPRange=Bitte IP-Range eingeben(xxx.xxx.xxx) :
SET /p AnfangsIP=Bitte AnfangsIP des Bereiches eingeben :
SET /p EndIP=Bitte EndIP des Bereiches eingeben :

FOR /L %%I IN (%AnfangsIP%,1,%EndIP%) DO (
    ping -n 1 %IPRange%.%%I | find "TTL=" >nul
    if errorlevel 1 (
        echo %IPRange%.%%I not reachable
    ) else (
        echo %IPRange%.%%I reachable
    )
)

pause>nul

编辑：添加了输出示例

C:\> test.bat
Bitte IP-Range eingeben(xxx.xxx.xxx) :127.0.0
Bitte AnfangsIP des Bereiches eingeben :0
Bitte EndIP des Bereiches eingeben :7
127.0.0.0 not reachable
127.0.0.1 reachable
127.0.0.2 reachable
127.0.0.3 reachable
127.0.0.4 reachable
127.0.0.5 reachable
127.0.0.6 reachable
127.0.0.7 reachable

Answer 2

He Guys

非常感谢你的回答。最后，Aacini的剧本有效。随着时间的推移，我制作了一个没有任何for循环的脚本，并不是那么漂亮......

以下是代码：

@ECHO off
COLOR F0

:START
BREAK>PINGLOG.txt

CLS
SET /P range=Bitte IP-Range eingeben(xxx.xxx.xxx):
CLS
SET /P sIP=Bitte Start-IP eingeben(xxx):
CLS
SET /P eIP=Bitte End-IP eingeben(xxx):
CLS

SET /P JN1=START PING FROM %range%.%sIP% - %range%.%eIP%?(Y/N):

CLS
SET /A counter=%sIP%
SET /A endIP=%eIP%
SET /A endIP+=1
CLS

IF /I %JN1%==Y (
    GOTO PINGRANGE
) ELSE (
    GOTO ENDE2
)

:PINGRANGE
COLOR 7C
PING -n 1 %range%.%counter% | find "TTL=" >nul
IF NOT ERRORLEVEL 1 (
    ECHO ------------------------------------------------- >>PINGLOG.txt
    ECHO %range%.%counter% is reachable! >>PINGLOG.txt
    ECHO %range%.%counter% is reachable!
) ELSE (
    ECHO %range%.%counter% is not reachable!
)

SET /A counter+=1
GOTO CHECK
)

:CHECK
IF %counter%==%endIP% (
    GOTO ENDE1
) ELSE (
    GOTO PINGRANGE
)

:ENDE1
COLOR F0
ECHO -------------------------------------------------
SET /P JN2= FINISH! WOULD YOU SEE THE LOGFILE?(Y/N):
IF /I %JN2%==Y (
    START NOTEPAD "PINGLOG.txt"
) ELSE (
    EXIT cmd.exe
)

:ENDE2
COLOR F0
ECHO -------------------------------------------------
SET /P JN3= NEW IP-RANGE PING?(Y/N):
IF /I %JN3%==Y (
    GOTO START
) ELSE (
    EXIT cmd.exe
)

我现在认为这不是很漂亮:)。

祝你有个美好的一天卢卡斯

使用批处理用户定义的IP范围

2 个答案: