Question

我有两个文件，如下所示：

File1中：

chr id position a0 a1
22 rs4820378:39869209:C:T 39869209 C T
22 22:16050075:A:G 16050075 A G
22 22:16050115:G:A 16050115 G A
22 rs199694733:39913976:C:CT 39913976 C CT
22 rs139408809:39937958:GC:G 39937958 GC G

文件2：

SNP CHR BP A1 A2
rs4820378 22 39869209 C T
rs4821900 22 39869719 G A
rs1984662 22 39869997 T G
rs35629588 22 39913976 I2 D
rs139408809 22 39937958 D I2

我想找到

行

File1中的字段1和3匹配来自File2

也是

File1中的字段4和5匹配来自File2的字段4和5
两个文件中的字段4都有超过1个字符
两个文件中的字段5都有超过1个字符

然后从File1打印出字段2，从File2打印字段1和3

以下代码

#! perl -w

use strict;
use warnings;

my %kglocus;
open( my $loci_in, "<", "File1" ) or die $!;
while ( <$loci_in> ) {

    next if m/chr/;

    my ( $CHR, $id, $BP, $A1, $A2 ) = split;
    my $reg = "${CHR}_$BP";
    $kglocus{$reg} = [ $CHR, $id, $BP, $A1, $A2 ];
}
close $loci_in;

my $filename = shift @ARGV;
open( my $input, "<", $filename ) or die $!;
while ( <$input> ) {
    next if m/SNP/;

    my ( $SNP, $CHR, $BP, $A1, $A2 ) = split;
    my $reg = "${CHR}_$BP";

    if ( $A1 eq $kglocus{$reg}->[3] and $A2 eq $kglocus{$reg}->[4] ) {

        print "$kglocus{$reg}->[1] $SNP $BP\n";
    }
    elsif ( ( length( $A1 ) > 1 && length( $kglocus{$reg}->[3] ) > 1 ) ||
            ( length( $A2 ) > 1 && length( $kglocus{$reg}->[4] ) > 1 ) ) {

        print "$kglocus{$reg}->[1] $SNP $BP\n";
    }
}

close( $input );

我收到以下所有输入行的错误：

Use of uninitialized value in string eq at find_ID.hash.chr22.pl line 23 
Use of uninitialized value in length at find_ID.hash.chr22.pl line 27

有人可以指出问题吗？

Answer 1

问题是哈希元素$kglocus{$reg}的存在形成了第一个测试，＆＃34;来自File1的字段1和3匹配来自File2＆＃34的字段2和3; 。但是你把它当作测试总是通过，只是用它来访问File1记录的元素

你需要像next unless $kglocus{$reg}之类的东西才能使它正常工作。我还希望看到这个值作为一个单独的变量被拉出来，以避免反复索引哈希值

这是一个适合你的解决方案

use strict;
use warnings;
use v5.10.1;
use autodie;

my %kglocus;
{
    open my $in_fh, '<', 'File1';
    while ( <$in_fh> ) {
        next if /chr/;

        my ( $chr, $id, $bp, $a1, $a2 ) = split;
        my $key = "${chr}_$bp";
        $kglocus{$key} = [ $chr, $id, $bp, $a1, $a2 ];
    }
}

{
    my ( $filename ) = @ARGV;
    open my $in_fh, '<', $filename;
    while ( <$in_fh> ) {
        next if /SNP/;

        my ( $snp, $chr, $bp, $a1, $a2 ) = split;
        my $key = "${chr}_$bp";
        next unless my $item = $kglocus{$key};

        if ( $a1 eq $item->[3] and $a2 eq $item->[4]
                or length $a1 > 1 and length $item->[3] > 1
                or length $a2 > 1 and length $item->[4] > 1 ) {

            print "$item->[1] $snp $bp\n";
        }
    }
}

perl用两个文件中的匹配字段打印行，错误：在字符串中使用未初始化的值

1 个答案: