Question

如何在AMD64架构的Linux汇编程序中使用RIP相对寻址？我正在寻找一个使用AMD64 RIP相对地址模式的简单示例（Hello world程序）。

例如，以下64位汇编程序可以使用普通（绝对寻址）：

.text
    .global _start

_start:
    mov $0xd, %rdx

    mov $msg, %rsi
    pushq $0x1
    pop %rax
    mov %rax, %rdi
    syscall

    xor %rdi, %rdi
    pushq $0x3c
    pop %rax
    syscall

.data
msg:
    .ascii    "Hello world!\n"

我猜测使用RIP相对寻址的相同程序会是这样的：

.text
    .global _start

_start:
    mov $0xd, %rdx

    mov msg(%rip), %rsi
    pushq $0x1
    pop %rax
    mov %rax, %rdi
    syscall

    xor %rdi, %rdi
    pushq $0x3c
    pop %rax
    syscall

msg:
    .ascii    "Hello world!\n"

正常版本在编译时运行正常：

as -o hello.o hello.s && ld -s -o hello hello.o && ./hello

但我无法使RIP版本正常工作。

有什么想法吗？

---编辑----

Stephen Canon的回答使RIP版本有效。

现在当我反汇编RIP版本的可执行文件时，我得到了：

objdump -d hello

0000000000400078 <.text>:
  400078: 48 c7 c2 0d 00 00 00  mov    $0xd,%rdx
  40007f: 48 8d 35 10 00 00 00  lea    0x10(%rip),%rsi        # 0x400096
  400086: 6a 01                 pushq  $0x1
  400088: 58                    pop    %rax
  400089: 48 89 c7              mov    %rax,%rdi
  40008c: 0f 05                 syscall 
  40008e: 48 31 ff              xor    %rdi,%rdi
  400091: 6a 3c                 pushq  $0x3c
  400093: 58                    pop    %rax
  400094: 0f 05                 syscall 
  400096: 48                    rex.W
  400097: 65                    gs
  400098: 6c                    insb   (%dx),%es:(%rdi)
  400099: 6c                    insb   (%dx),%es:(%rdi)
  40009a: 6f                    outsl  %ds:(%rsi),(%dx)
  40009b: 20 77 6f              and    %dh,0x6f(%rdi)
  40009e: 72 6c                 jb     0x40010c
  4000a0: 64 21 0a              and    %ecx,%fs:(%rdx)

这显示了我想要完成的事情：lea 0x10（％rip），％rsi在地址0x400096之后的地址为0x400096的地址加载地址17个字节，其中可以找到Hello世界字符串，从而产生与位置无关的代码。

Answer 1

我认为您要将字符串的地址加载到%rsi;您的代码尝试从该地址加载四字而不是地址本身。你想要：

lea msg(%rip), %rsi

如果我没有弄错的话。但是，我没有要测试的linux盒子。

Answer 2

由于您需要％rsi中味精的地址，因此只需替换：

mov msg(%rip),%rsi

具有：

lea msg(%rip),%rsi

如何在64位汇编程序中使用RIP相对寻址？

2 个答案: