Question

我有一个要求，我将以下面的格式获取网址 https://sample.com?first=one&second=two&third=three

如何在下面形成一个xml结构，该结构将通过使用此查询参数

形成

{{1}}

可以请有人帮我这个并为我提供xslt这个要求

Answer 1

给出以下 XML 输入（请注意＆符号的转义）：

<URL>https://sample.com?first=one&amp;second=two&amp;third=three</URL>

下面的样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <output>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after(URL, '?')"/>
        </xsl:call-template>
    </output>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'&amp;'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <xsl:element name="{substring-before($token, '=')}">
                <xsl:value-of select="substring-after($token, '=')"/>
            </xsl:element>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

将返回：

<?xml version="1.0" encoding="UTF-8"?>
<output>
   <first>one</first>
   <second>two</second>
   <third>three</third>
</output>

请注意，仅当查询字段名称也是有效的XML元素名称时才会起作用。

如何在XSLT中解析查询参数

1 个答案: